*     ************  DEPMENU.CMD COMMAND FILE  **********
* Select deposits or perform housekeeping on the checkbook.
*********************************************************

STORE T TO Incoming
DO WHILE Incoming
  ERASE
  @  5,20 SAY '    1> ENTER MONEY COMING IN    '
  @  7,20 SAY '    2> CHANGE OUR CHECK NUMBER  '
  @  9,20 SAY '    3> CHANGE CHECKBOOK BALANCE '
  ?
  ?
  ? '                                <RETURN>'
  WAIT TO Action

  IF Action = '1'
     DO Deposits
  ELSE
     IF Action = '2'
        RESTORE FROM B:Constant
        ERASE 
        @ 5,0 SAY 'This is the next check number' GET NextCheck
        @ 6,0 SAY 'To leave it unchanged, use the <return>.'
        @ 7,0 SAY 'To change it, just type in the new number.'
        READ
        SAVE TO B:Constant
        RELEASE All
     ELSE
	IF Action = '3'
	   RESTORE FROM B:Constant
           STORE 'Y' TO Change
	   DO WHILE !(Change) = 'Y'
	      ERASE
              @ 5,0 SAY '     The current balance is:' GET MBalance
	      ? 'To leave it unchanged, use the <return>.'
	      ? 'To change it, just type in the new value.'
	      READ
	      ?
	      ?
	      ? '	Want to change your mind (Y or N)?'
	      WAIT TO Change
	   ENDDO
	   RELEASE Change
	   SAVE TO B:Constant
	   RELEASE All
        ELSE
	   RELEASE All
           RETURN
        ENDIF 3
     ENDIF 2
  ENDIF 1
  ERASE
  STORE T TO Incoming
ENDDO Incoming
