* INVENTOR.CMD
* WRITTEN BY MICHAEL LYNN  8/3/83
SELE SECO
DO WHILE T
ERASE
?
?
? ' -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-'
?
? '    ****INVENTORY REPORTS & UPDATING****'
?
? ' 1  REPORT OF INSTOCK INVENTORY'
? 
? ' 2  REPORT OF ITEMS WITH QUANTITIES BELOW'
? '           A CERTAIN NUMBER'
?
? ' 3  REPORT OF ITEMS BELOW STANDARD RE-ORDER POINT' 
?
? ' 4  COMPLETE INVENTORY LIST'
?
? ' 5  ITEM LISTING FOR PARTICULAR VENDOR'
?
? ' 6  RETURN TO MAIN MENU'
?
? ' =-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-='
?
SET CONSOLE OFF
WAIT TO what
SET CONSOLE ON

IF what < '6'
@ 22, 1 SAY 'ENTER A Y TO GET A PRINTED COPY OF REPORT'
SET CONSOLE OFF
WAIT TO print
SET CONSOLE ON
   IF !(print) = 'Y'
   SET PRINT ON
   SET EJECT OFF
   RELEASE print
   ENDIF
ENDIF
ERASE
DO CASE    

CASE WHAT ='1'
SET HEAD TO STOCK ON HAND
ERASE
REPORT FORM B:INVENTOR FOR QUANTITY > 0
EJECT
SET PRINT OFF
SET CONSOLE OFF
WAIT
SET CONSOLE ON

CASE WHAT ='2'
STORE 0 TO mmin
@ 19, 1 SAY "ENTER MINIMUM NUMBER FOR INVENTORY" GET mmin PICTURE '9'
READ
STORE STR(mmin,1) TO min
SET HEAD TO ITEMS WITH INVENTORY OF &min OR BELOW
ERASE
REPORT FORM B:INVENTOR FOR QUANTITY <= &min
SET CONSOLE OFF
WAIT
SET CONSOLE ON
RELE mmin, min
EJECT
SET PRINT OFF

CASE what ='3'
SET HEAD TO ITEMS WITH QUANTITY BELOW RE-ORDER POINT
ERASE
REPORT FORM B:INVENTOR FOR quantity < reorder
EJECT
SET PRINT OFF
SET CONSOLE OFF
WAIT
SET CONSOLE ON

CASE what ='4'
SET HEAD TO ***COMPLETE ITEM LISTING***
ERASE
REPORT FORM B:INVENTOR 
EJECT
SET PRINT OFF
SET CONSOLE OFF
WAIT
SET CONSOLE ON

CASE what ='5'
STORE 00 TO mvend
@ 19, 1 SAY "ENTER VENDOR NUMBER" GET mvend PICTURE '99'
READ
STORE STR(mvend,2) TO ven
SET HEAD TO ITEMS SUPPLIED BY VENDOR &ven
ERASE
REPORT FORM B:INVENTOR FOR vendor = &ven
SET CONSOLE OFF
WAIT
SET CONSOLE ON
RELE mvend, ven
EJECT
SET PRINT OFF

CASE WHAT ='6'
SET PRINT OFF
ERASE
RELEASE what
RETURN

ENDCASE
ENDDO
