         *****************  PRINTOUT COMMAND FILE  ****************
* This file is used by several other command files.  It prints out a
* listing of the records in a file without the record number.  The
* output is spaced every 10 records and the printer is positioned back
* at the left margin after the printout.
*      The calling command file determined where the printout starts by
* specifying a value for the variable "Number".
*      This does not show the record numbers.  To do so, use the 
* Review.CMD file.
**********************************************************************

IF VAL(Number) > 0
   GOTO RECORD &Number
ELSE
   GO TOP
ENDIF

STORE 0 TO Count
DO WHILE .NOT. EOF
   IF *
      SKIP
   ELSE
      DISPLAY &Condition
      SKIP
      STORE Count + 1 TO Count
      IF Count = 10
         STORE 0 TO Count
         * Spaces one line every 10 records, then waits.  Turns the printer
         * off so that "WAIT" does not print.
         ?
         SET PRINT OFF
         WAIT
         IF !(Output) = 'Y'
            SET PRINT ON
         ENDIF
      ENDIF
   ENDIF
ENDDO
* The next 2 lines reposition the printer at the
* left margin.
?
SET PRINT OFF

RELEASE Count, Output
RETURN
