0 WIDTH 255
10 'DOG STAR BY LANCE MICKLUS
20 REM Converted into Microsoft basic by Robert Nelson
150 CLEAR 200:DEFINT A-Z	
151 CLS$=CHR$(27)+"E" 'ERASE SCREEN
200 GOSUB 30300
210 BT=1
450 LC=2:SL=64:BL=4:GF=50:RV=16396
600 GOTO 10300
2125 IF TC<25 OR RND(GF)<>1 THEN 2425
2150 IF TC=300 THEN GF=20
2175 IF LC<3 OR LC=9 OR LC=26 OR LC=36 OR LC=37 THEN 2425
2200 IF LC>26 AND LC<31 THEN 2425
2225 PRINT "HOLY SMOKES. AN ARMED GUARD JUST WALKED IN."
2250 GOSUB 20350: IF VB<>12 OR NO<>15 THEN 5575
2275 X=13: GOSUB 21450: IF Y<>-1 THEN 5575
2300 IF BL=0 THEN PRINT CLS$;: PRINT "I'M OUT OF AMMUNITION.": PRINT :GOTO 5600
2325 PRINT "ZZZAP! NO MORE GUARD."
2350 BL=BL-1: IF BL=0 THEN PRINT "I'M OUT OF AMMUNITION
2425 IF MD<>TC THEN 2550
2450 X=22: GOSUB 21450: IF Y<>-1 THEN 2550
2475 PRINT "YOUR BIG-MAC IS COLD.
2550 GOSUB 20350:TC=TC+1
2575 IF VB=0 AND NO=0 THEN 2650 ELSE 2800
2650 PRINT "I DON'T KNOW HOW TO DO THAT.":GOTO 2125
2725 PRINT "NOTHING HAPPENED.":GOTO 2125
2800 IF VB>1 OR NO>7 THEN 3175
2825 IF NO=0 THEN 2650
2850 IF DS(LC,NO-1)=0 THEN PRINT "I CAN'T GO THAT WAY!":GOTO 2125
2875 IF DR AND DS(LC,NO-1)>2 AND DS(LC,NO-1)<6 THEN PRINT "I CAN'T GO THAT WAY. FLIGHT DECK DO OR S ARE OPEN."+CHR$(13)+CHR$(10)+"NO AIR!!!":GOTO 2125
2900 IF NO=3 AND LC=31 AND NOT DJ THEN PRINT M0$:GOTO 2125
2925 IF LC=35 AND DS(LC,NO-1)=36 AND OB(21,1)<>0 THEN PRINT "THE ROBOT WON'T LET ME THRU.":GOTO 2125
2950 IF LC=17 AND OB(13,1)=17 THEN 5575
2975 IF LC=9 AND OB(5,1)=9 THEN 5575
3000 IF LC=9 OR LC=17 THEN HE$(LC)=""
3025 LC=DS(LC,NO-1)
3050 IF LC=34 THEN HE$(LC)=""
3075 IF LC=26 THEN 11800
3100 GOTO 10300
3175 IF VB=3 THEN 10300
3250 IF VB<>2 THEN 3700
3275 IF NO=0 THEN PRINT "I DON'T KNOW WHAT A ";CHR$(34);NO$(0);CHR$(34);" IS.":GOTO 2125
3300 IF CR>5 THEN PRINT "I CAN'T CARRY ANY MORE HINT: DROP SOMETHING.)":GOTO 2125
3325 FOR I=1 TO LO: IF OB(I,0)=NO THEN 3350 ELSE NEXT I:GOTO 2650
3350 IF OB(I,1)=-1 THEN PRINT "I'M ALREADY CARRYING IT.":GOTO 2125
3375 IF OB(I,1)<>LC THEN PRINT "I DON'T SEE IT.":GOTO 2125
3400 IF NO<>37 THEN 3475
3425 X=13: GOSUB 21450: IF Y<>-1 THEN PRINT "I DON'T HAVE A BLASTER TO PUT IT IN.":GOTO 2125
3450 BL=4:OB(I,1)=0: PRINT "MY BLASTER'S RELOADED.":GOTO 2125
3475 IF NO=15 OR NO=25 OR NO=34 THEN PRINT "HE LOOKS PRETTY MEAN TO ME.":GOTO 2125
3500 CR=CR+1:OB(I,1)=-1: PRINT "OK"
3525 IF NO=14 AND NOT CM THEN PRINT "A VOICE SAYS: ";CHR$(34);"SESAME";CHR$(34);".":CM=-1
3550 IF NO=22 AND MD=0 THEN MD=TC+50
3575 IF NO=12 THEN HE$(2)=""
3600 IF NO=13 THEN HE$(7)=""
3625 GOTO 2125
3700 IF VB<>4 THEN 3875
3725 PRINT "I'M CARRYING:
3750 K=0:FOR I=1 TO LO: IF OB(I,1)=-1 THEN PRINT OB$(I):K=1
3775 NEXT I: IF K=0 THEN PRINT "NOTHING
3800 PRINT :GOTO 2125
3875 IF VB<>5 THEN 3950 ELSE GOSUB 21050:GOTO 2125
3950 IF VB<>6 THEN 4200
3975 IF NO=0 THEN 3275
4000 IF LC=2 THEN PRINT "THERE'S NO ROOM HERE.":GOTO 2125
4025 IC=0:FOR I=1 TO LO: IF OB(I,1)=LC THEN IC=IC+1
4050 NEXT I: IF IC>12 THEN PRINT "THERE'S NOT ENOUGH ROOM. GET RID OF SOMETHING.":GOTO 2125
4075 FOR I=0 TO LO: IF OB(I,0)=NO THEN 4100 ELSE NEXT I:GOTO 2650
4100 IF OB(I,1)<>-1 THEN PRINT "I'M NOT CARRYING IT.":GOTO 2125
4125 CR=CR-1:OB(I,1)=LC: PRINT "O.K.":GOTO 2125
4200 IF VB<>7 THEN 4300
4225 IF HE$(LC)="" THEN PRINT "HOW AM I SUPPOSED TO KNOW WHAT TO DO?":GOTO 2125 ELSE PRINT HE$(LC):GOTO 2125
4300 IF VB<>8 THEN 4750
4375 IF NOT BT THEN 4475 ELSE PRINT "PRESS ENTER WHEN READY TO RECORD"
4400 GOSUB 22000:GOTO 4525
4475 IF NO$(0)="" THEN PRINT "TRY SOMETHING LIKE ";CHR$(34);VB$(0);" FILESPEC";CHR$(34);".":GOTO 2125
4500 OPEN "O",1,NO$(0)
4525 FOR I=0 TO LO
4550 PRINT  #1,OB(I,0);OB(I,1);OB(I,2)
4575 NEXT I
4600 REM
4625 PRINT #1,TB;TC;CM;DR;BL;MD;GF;DJ;CR;LC
4650 CLOSE
4675 PRINT "O.K.":GOTO 2125
4750 IF VB<>9 THEN 5150
4825 GOTO 4925
4850 GOSUB 22000:GOTO 4975
4925 IF NO$(0)="" THEN 4475
4950 OPEN "I",1,NO$(0)
4975 FOR I=0 TO LO
5000 INPUT#1,OB(I,0),OB(I,1),OB(I,2)
5025 NEXT I
5075 INPUT#1,TB,TC,CM,DR,BL,MD,GF,DJ,CR,LC
5100 CLOSE
5125 GOTO 10300
5150 IF VB<>10 THEN 5225 ELSE PRINT CLS$:J=0:GOTO 11200
5225 IF VB<>11 THEN 5725
5250 IF NO<>10 THEN 2650
5275 IF LC<>2 AND LC<>11 THEN PRINT "WHAT BUTTON,":GOTO 2125
5300 IF LC=11 AND NOT TB THEN LET TB=-1: PRINT N2$:GOTO 2125
5325 IF LC=11 AND TB THEN LET TB=0: PRINT N3$:GOTO 2125
5375 X=12: GOSUB 21450: IF Y<>1 THEN 2725
5425 X=24: GOSUB 21450: IF Y<>1 THEN 2725
5450 IF NOT TB THEN PRINT N3$:GOTO 2725
5475 IF NOT DR THEN PRINT N4$:GOTO 2725
5500 GOTO 11150
5575 PRINT CLS$;: PRINT "H E L P ! ! !": PRINT 
5600 PRINT "ROCHE SOLDIERS ARE EVERYWHERE. I'VE BEEN CAPTURED."+CHR$(13)+CHR$(10)+"I'M NOW A PRISONER."+CHR$(13)+CHR$(10)+"WOE IS ME. . .
5650 GOTO 11500
5725 IF VB<>12 OR NO=0 THEN 6025
5750 IF BL=0 THEN PRINT "BUT I DON'T HAVE ANY AMMUNITION LEFT.":GOTO 2125
5775 X=13: GOSUB 21450: IF Y<>-1 THEN PRINT "BUT I'M NOT CARRYING A BLASTER.":GOTO 2125
5800 X=NO: GOSUB 21450: IF Y=-1 THEN PRINT "I CAN'T. I'M HOLDING IT.":GOTO 2125
5825 IF NO=34 THEN PRINT "ZZZAP!":BL=BL-1:GOTO 2125
5850 IF Y<>LC THEN PRINT "I DON'T SEE IT.":GOTO 2125
5875 FOR I=1 TO LO: IF OB(I,0)=NO THEN 5900 ELSE NEXT I:GOTO 2650
5900 OB(I,1)=0:FOR I=1 TO 1:NEXT I: PRINT "ZZZAP THE ";NO$(NO);" VAP OR IZED."
5925 BL=BL-1: IF BL=0 THEN PRINT "I'M OUT OF AMMUNITION."
5950 GOTO 2125
6025 IF VB<>13 THEN 6275
6050 IF NO=0 THEN PRINT "SAY WHAT?":GOTO 2125
6075 X=14: GOSUB 21450
6100 IF Y<>-1 OR NO<>19 THEN PRINT "O.K.  ";NO$(NO):GOTO 2125
6125 IF DR GOTO 2725
6150 DR=-1: PRINT "A VOICE COMES OVER THE P.A. SYSTEM AND SAYS:"+CHR$(13)+CHR$(10)+"OPENNING FLIGHT DECK DOORS"
6175 IF LC>2 AND LC<6 THEN PRINT CHR$(13)+CHR$(10)+"YIPES ! ! ! THERE'S NO AIR ! ! ! CROAK ...":END
6200 GOTO 2125
6275 IF VB<>14 THEN 6750
6300 IF NO<>20 AND NO<>16 AND NO<>11 AND NO<>33 THEN 2650
6325 IF NO=20 THEN 6550
6350 IF NO<>16 THEN 6450
6375 IF OB(6,1)=-1 THEN PRINT "SORRY. I'M NOT A MAP-MAKER":GOTO 2125
6400 IF OB(6,1)=LC THEN PRINT "TRY GET MAP.":GOTO 2125
6425 PRINT "IT'S NOT HERE.":GOTO 2125
6450 X=NO: GOSUB 21450: IF Y<>LC AND Y<>-1 THEN 6425
6475 IF NO=11 THEN PRINT "IT SAYS: >> NEEDS TURBO <<"
6500 INNO=33 THEN THEN PRINT "IT SAYS: >> OUT OF ORDER <<"
6525 GOTO 2125
6550 IF LC<>13 THEN PRINT "I DON'T SEE ANY.":GOTO 2125
6575 PRINT : PRINT "IT SAYS ON THE WALL,"+CHR$(13)+CHR$(10)+"   YOUR MOTHER'S GOT A BIG NOSE"+CHR$(13)+CHR$(10)+"   KILROY MADE IT HERE, TOO"+CHR$(13)+CHR$(10)+"   SAY SECURITY
6675 GOTO 2125
6750 IF VB<>15 THEN 6975
6775 IF NO=0 THEN PRINT "WHAT'S A ";NO$(0);"?":GOTO 2125
6800 IF NO<>22 THEN PRINT "DON'T BE RIDICULOUS.":GOTO 2125
6825 X=22: GOSUB 21450: IF Y<>-1 THEN PRINT "I'M NOT HOLDING IT.":GOTO 2125
6850 FOR I=1 TO LO: IF OB(I,0)=22 THEN 6875 ELSE NEXT I: PRINT "I DON'T KNOW WHERE IT IS.":GOTO 2125
6875 OB(I,1)=0: PRINT "CHUMP - CHUMP. HUMMM, GOOD."
6900 FOR I=1 TO 1:NEXT I:GOTO 2125
6975 IF VB<>16 OR NO<>23 OR LC<>16 THEN 7125
7000 X=23: GOSUB 21450: IF Y<>-1 THEN PRINT M1$:GOTO 2125
7025 OB(11,1)=0:OB(14,1)=16:CR=CR-1: PRINT M2$
7050 GOTO 2125
7125 IF VB<>18 OR NO<>36 THEN 7275
7150 IF NO<>36 OR LC<>31 THEN 2650
7175 X=17: GOSUB 21450: IF Y<>-1 THEN PRINT M3$:GOTO 2125
7200 HE$(31)="":DJ=-1: PRINT M4$:GOTO 2125
7275 IF VB<>19 OR NO=0 THEN 7600
7300 IF NO<>34 THEN PRINT "THAT'S STUPID!":GOTO 2125
7325 IF LC<>35 THEN PRINT M5$:GOTO 2125
7350 X=22: GOSUB 21450: IF Y<>-1 THEN PRINT M6$:GOTO 2125
7375 IF NO=35 THEN PRINT M7$:GOTO 2125
7400 IF NO<>34 THEN PRINT NO$(0);M8$:GOTO 2125
7425 IF TC>MD THEN PRINT M9$:GOTO 2125
7450 FOR I=1 TO LO: IF OB(I,0)=34 THEN 7475 ELSE NEXT I:GOTO 2650
7475 K=I:FOR I=1 TO LO: IF OB(I,0)=22 THEN 7500 ELSE NEXT I:GOTO 2650
7500 PRINT N0$:HE$(35)=""
7525 OB(K,1)=0:OB(I,1)=0:FOR I=1 TO 1:NEXT I:GOTO 2125
7600 IF VB<>17 THEN 7700
7625 PRINT NO$(0):GOTO 2125
7700 IF VB<>20 THEN 7975
7725 IF NO=0 THEN 2650
7750 X=NO: GOSUB 21450: IF Y=-1 THEN PRINT "I'M CARRYING IT. THAT'S IMPOSSIBLE":GOTO 2125
7775 IF Y=LC THEN 7850
7800 IF NO<11 OR NO=19 OR NO=20 OR NO=30 THEN 2650
7825 PRINT "I CAN'T HIT SOMETHING I CAN'T SEE.":GOTO 2125
7850 IF NO=15 OR NO=34 THEN PRINT "I'D RATHER NOT. HE MIGHT HIT ME BACK!":GOTO 2125
7875 IF NO=35 THEN PRINT "THAT'S NOT NICE!":GOTO 2125
7900 GOTO 2725
7975 IF VB<>21 THEN 8000 ELSE PRINT "I'M NOT STRONG ENOUGH TO KILL ANYTHING.":GOTO 2125
8000 GOTO 2650
10300 PRINT CLS$;: PRINT DS$(LC):A$=""
10305 IF LC=35 THEN GF=10
10400 IF LC=7 THEN 10700
10450 K=0:FOR I=1 TO LO: IF OB(I,1)<>LC THEN 10600
10500 IF K=0 THEN K=1: PRINT : PRINT "AROUND ME I SEE:":A$=OB$(I):GOTO 10600
10550 IF LEN(A$)+5+LEN(OB$(I))>SL THEN PRINT A$:LET A$=OB$(I) ELSE A$=A$+"   "+OB$(I)
10600 NEXT I
10650 IF A$<>"" THEN PRINT A$
10700 PRINT : PRINT "OBVIOUS DIRECTIONS ARE ";:K=0
10750 FOR I=0 TO 5: IF DS(LC,I)=0 THEN 10900
10800 IF K<>0 THEN PRINT ", ";
10850 PRINT NO$(I+1);:K=1
10900 NEXT I
10950 IF K=0 THEN PRINT "UNKNOWN";
11000 PRINT ".":GOTO 2125
11150 PRINT CLS$: GOSUB 21050
11200 IF J=0 THEN PRINT "WE HAVE FAILED OUR MISSION.	"+CHR$(13)+CHR$(10)+"THE FORCES OF PRINCESS LEYA WILL BE CONQUERED."
11250 IF J=SC THEN PRINT "WE ARE HEROS."+CHR$(13)+CHR$(10)+"THE FORCES OF PRINCESS LEYA WILL CONQUER THE EVIL ROCHE SOLDIERS AND FREEDOM WILL PREVAIL THROUGHOUT THE GALAXY."
11300 IF J>0 AND J<SC THEN PRINT "WE HAVE HELPED THE FORCES OF PRINCESS LEYA"+CHR$(13)+CHR$(10)+"DEFEND THE GALAXY. LONG LIVE THE FORCES OF FREEDOM!"
11500 PRINT 
11550 INPUT"PLAY AGAIN (Y OR N)";A$:A$=LEFT$(A$,1)
11600 IF A$="Y" THEN 150 ELSE END
11800 PRINT CLS$;: PRINT "A VOICE BOOMS OUT, ";CHR$(34);"WHO GOES THERE";CHR$(34)
11850 GOSUB 20350
11900 IF VB<>13 OR NO<>30 THEN 5575
11950 PRINT N1$
12000 GOSUB 20350
12050 X=31: GOSUB 21450: IF Y<>-1 THEN 5575
12100 IF VB<>17 OR NO<>31 THEN 5575 ELSE 10300
20350 INPUT"WHAT SHOULD I DO";CM$
20395 VB$(0)="":NO$(0)="":VB=0:NO=0: IF LEN(CM$)=0 THEN RETURN
20400 FOR ZL=1 TO LEN(CM$): IF MID$(CM$,ZL,1)<>" " THEN VB$(0)=VB$(0)+MID$(CM$,ZL,1):NEXT ZL
20500 FOR ZL=1 TO LV: IF VB$(ZL)<>"" AND LEFT$(VB$(0),LEN(VB$(ZL)))=VB$(ZL) THEN VB=ZL:GOTO 20600
20501 NEXT ZL
20550 VB=0:NO$(0)=VB$(0):GOTO 20650
20600 IF LEN(VB$(0))+1>=LEN(CM$) THEN NO=0:RETURN ELSE NO$(0)=RIGHT$(CM$,LEN(CM$)-1-LEN(VB$(0)))
20650 FOR ZL=1 TO LN: IF NO$(ZL)<>"" AND LEFT$(NO$(0),LEN(NO$(ZL)))=NO$(ZL) THEN NO=ZL:GOTO 20800 ELSE NEXT ZL
20700 NO=0:RETURN
20800 FOR ZL=1 TO 1:NEXT ZL:RETURN
21050 J=0:FOR I=1 TO LO: IF OB(I,1)=1 THEN J=J+OB(I,2)
21100 NEXT I: PRINT "OUT OF A MAXIMUM OF";SC;"POINTS, YOU HAVE";J
21150 IF J=0 THEN PRINT "WE'RE NOT DOING TOO GOOD."
21200 RETURN
21450 FOR ZL=0 TO LO: IF OB(ZL,0)=X THEN Y=OB(ZL,1):GOTO 21500 ELSE NEXT ZL:Y=-99:RETURN
21500 FOR ZL=1 TO 1:NEXT ZL:RETURN
22000 A$=INKEY$
22010 IF A$="" THEN 22000 ELSE RETURN
30300 SC=215
30450 IF PEEK(16396)=201 THEN BT=-1 ELSE BT=0
30600 LV=21:DIM VB$(LV)
30650 VB$(1)="GO":VB$(2)="GET":VB$(3)="LOOK"
30700 VB$(4)="INVEN":VB$(5)="SCORE":VB$(6)="DROP"
30750 VB$(7)="HELP":VB$(8)="SAVE":VB$(9)="LOAD":VB$(10)="QUIT"
30800 VB$(11)="PRESS":VB$(12)="SHOOT":VB$(13)="SAY"
30850 VB$(14)="READ":VB$(15)="EAT":VB$(16)="CSAVE"
30900 VB$(17)="SHOW":VB$(18)="OPEN":VB$(19)="FEED"
30950 VB$(20)="HIT":VB$(21)="KILL"
31100 LN=37:DIM NO$(LN)
31150 NO$(1)="NORTH":NO$(2)="EAST":NO$(3)="SOUTH"
31200 NO$(4)="WEST":NO$(5)="UP":NO$(6)="DOWN"
31250 NO$(10)="BUTTON":NO$(11)="TAG":NO$(12)="FUEL"
31300 NO$(13)="BLASTER":NO$(14)="COMMUNICATOR":NO$(15)="GUARD"
31350 NO$(16)="MAP":NO$(17)="KEYS":NO$(18)="NECKLACE"
31400 NO$(19)="SESAME":NO$(20)="GRAFFITI"
31450 NO$(21)="CAPE":NO$(22)="HAMBURGER"
31500 NO$(23)="TAPE":NO$(24)="TURBO":NO$(25)="SCIENTIST":NO$(26)="PLANS":NO$(27)="SCHEMATIC":NO$(28)="DEVICE":NO$(29)="GUN"
31650 NO$(30)="SECURITY":NO$(31)="I.D.":NO$(32)="CRYSTALS":NO$(33)="SIGN":NO$(34)="ROBOT":NO$(35)="PRINCESS"
31750 NO$(36)="DOOR":NO$(37)="AMMUNITION"
31900 CL=37:DIM DS$(CL)
31950 DS$(1)="I'M IN THE PASSENGER & STORAGE COMPARTMENT OF MY SPACE SHIP."+CHR$(13)+CHR$(10)+"THERE'S AN EXIT HERE TO LEAVE THE SHIP.
32000 DATA 2,0,0,0,0,3
32050 DS$(2)="I'M IN THE COCKPIT OF MY SPACE SHIP."+CHR$(13)+CHR$(10)+"A LARGE RED BUTTON SAYS >> PRESS TO BLAST OFF <<
32100 DATA 0,0,1,0,0,0
32150 DS$(3)="I'M STANDING NEXT TO MY SPACE SHIP WHICH IS LOCATED ON A"+CHR$(13)+CHR$(10)+"HUGE FLIGHT DECK.
32200 DATA 18,0,4,0,1,0
32250 DS$(4)="I'M OUT ON THE FLIGHT DECK OF GENERAL DOOM'S BATTLE CRUISER
32300 DATA 3,5,4,4,0,0
32350 DS$(5)=DS$(4):DATA 4,6,5,4,0,0
32400 DS$(6)="I'M IN A HALLWAY. THERE ARE DOORS ON ALL SIDES"+CHR$(13)+CHR$(10)+"THE DOOR  TO THE NORTH SAYS: >> CLOSED FOR THE DAY <<
32450 DATA 7,0,8,5,0,0
32500 DS$(7)="I'M IN THE SUPPLY DEPOT"+CHR$(13)+CHR$(10)+"AROUND ME I SEE:"+CHR$(13)+CHR$(10)+"        ALL KINDS OF THINGS.
32550 DATA 0,0,6,0,0,0
32600 DS$(8)="I'M AT THE END OF ONE OF THE HALLWAYS"+CHR$(13)+CHR$(10)+"I CAN HEAR VOICES NEARBY. SOUNDS LIKE GUARDS.
32650 DATA 6,10,0,9,0,12
32700 DS$(9)="I'M IN THE STRATEGY PLANNING ROOM":DATA 11,8,0,0,0,0
32750 DS$(10)="I'M IN THE DECONTAMINATION AREA":DATA 0,14,0,8,0,0
32800 DS$(11)="THIS AREA IS THE TRACTOR BEAM CONTROL ROOM"+CHR$(13)+CHR$(10)+"A LARGE SIGN WARNS:"+CHR$(13)+CHR$(10)+"            >> DO NOT PRESS ANY BUTTONS <<
32850 DATA 0,0,9,0,0,0
32900 DS$(12)="I'M IN ANOTHER HALLWAY.  TO THE EAST IS A RESTROOM
32950 DATA 15,13,0,0,8,0
33000 DS$(13)="THIS IS WHAT IS COMMONLY CALLED, ON EARTH, THE BATHROOM"+CHR$(13)+CHR$(10)+"THERE'S GRAFFITI WRITTEN ALL OVER THE WALL."+CHR$(13)+CHR$(10)+"		PIPES LEAD UP THROUGH THE CEILING	
33050 DATA 15,0,0,12,27,0
33100 DS$(14)="THIS APPEARS TO BE AN INTERROGATION ROOM":DATA 0,0,0,10,0,0
33150 DS$(15)="I'M IN A LOUNGE":DATA 0,0,13,12,0,0
33200 DS$(16)="THIS IS A COMPUTER ROOM. THERE'S A TRS-80 IN HERE."+CHR$(13)+CHR$(10)+"ON THE SCREEN IT SAYS:"+CHR$(13)+CHR$(10)+"            >> CSAVE TAPE <<":DATA 17,0,18,0,0,0
33250 DS$(17)="I'M IN A TESTING LABORATOR Y":DATA 0,0,16,0,0,0
33300 DS$(18)="I'M IN A HALLWAY"+CHR$(13)+CHR$(10)+"A LARGE ARROW POINTS EAST AND SAYS:"+CHR$(13)+CHR$(10)+"            >> TO THE VAULT <<
33350 DATA 16,25,3,19,0,0
33400 DS$(19)="THIS IS THE ENTRANCE TO THE DEVELOPMENT LAB SECTION":DATA 20,18,21,20,22,0
33450 DS$(20)="I'M IN A LONG CORRIDOR. THERE ARE LABORATORIES ALL AROUND ME":DATA 19,23,21,20,22,24
33500 DS$(21)="I'M IN A RESEARCH LAB":DATA 20,0,0,0,0,0
33550 DS$(22)="I'M LOST!":DATA 22,22,22,22,22,20
33600 DS$(23)=DS$(21):DATA 0,0,0,20,0,0
33650 DS$(24)=DS$(21):DATA 0,0,0,0,20,0
33700 DS$(25)="I'M NEAR THE ENTRANCE TO THE VAULT"+CHR$(13)+CHR$(10)+"     A SIGN HERE SAYS:"+CHR$(13)+CHR$(10)+"           >> AUTHORIZED PERSONNEL ONLY <<	
33750 DATA 0,26,0,18,0,0
33800 DS$(26)="I'M IN THE VAULT":DATA 0,0,0,25,0,0
33850 DS$(27)="I'M IN A PIPE TUNNEL WHICH LEADS IN EVERY DIRECTION":DATA 28,27,27,27,27,13
33900 DS$(28)=DS$(27):DATA 29,29,29,29,30,29
33950 DS$(29)="I'M LOST IN A MAZE OF PIPES":DATA 28,29,29,29,29,27
34000 DS$(30)="I'M IN THE PIPE MAZE"+CHR$(13)+CHR$(10)+"BELOW ME I THINK I CAN SEE THE JAIL
34050 DATA 29,29,28,29,29,31
34100 DS$(31)="I'M IN THE JAIL":DATA 32,33,34,35,0,0
34200 DS$(32)="I'M IN A JAIL CELL":DATA 0,0,31,0,0,0
34250 DS$(33)=DS$(32):DATA 0,0,0,31,0,0
34300 DS$(34)=DS$(32):DATA 31,0,0,0,0,0
34350 DS$(35)="I'M AT THE SECURITY DESK"+CHR$(13)+CHR$(10)+" TO THE NORTH THERE'S AN ELEVATOR ":DATA 36,31,0,0,0,0
34400 DS$(36)="I'M IN THE ELEVATOR ":DATA 0,0,35,0,37,0
34450 DS$(37)=DS$(36):DATA 0,0,14,0,0,36
34850 LO=23:DIM OB$(LO)
34900 OB$(1)="A TAG WHICH SAYS:"+CHR$(13)+CHR$(10)+"      >> NEEDS TURBO <<":DATA 11,5,0
34950 OB$(2)="ANTI-MATTER FUEL":DATA 12,5,5
35000 OB$(3)="BLASTER":DATA 13,7,0
35050 OB$(4)="COMMUNICATOR ":DATA 14,9,0
35100 OB$(5)="A VERY SURPRISED GUARD":DATA 15,9,0
35150 OB$(6)="A MAP OF THE SHIP":DATA 16,29,20
35200 OB$(7)="SOME KEYS":DATA 17,9,0
35250 OB$(8)="A SHINESTONE NECKLACE":DATA 18,10,20
35300 OB$(9)="PRINCESS LEYA'S CAPE":DATA 21,14,5
35350 OB$(10)="MCDONALD'S HAMBURGER":DATA 22,15,0
35400 OB$(11)="A CASSETTE TAPE":DATA 23,7,0
35450 OB$(12)="A TURBOENCABULATOR ":DATA 24,17,5
35500 OB$(13)="AN EVIL LOOKING SCIENTIST":DATA 25,17,0
35550 OB$(14)="SECRET ATTACK PLANS":DATA 26,0,20
35600 OB$(15)="DEATH RAY SCHEMATIC":DATA 27,9,20
35650 OB$(16)="CLOAKING DEVICE":DATA 28,17,20
35700 OB$(17)="MICRO LASER GUN":DATA 29,24,20
35750 OB$(18)="I.D. CARD":DATA 31,17,0
35800 OB$(19)="MALIDIUM CRYSTALS (THE TREASURY!)":DATA 32,26,30
35850 OB$(20)="A SIGN WHICH SAYS:"+CHR$(13)+CHR$(10)+"        >> OUT OF ORDER <<":DATA 33,3,0 
35900 OB$(21)="ATTACK ROBOT":DATA 34,35,0
35950 OB$(22)="PRINCESS LEYA":DATA 35,34,50
36000 OB$(23)="AMMUNITION":DATA 37,7,0
36150 DIM DS(CL,5):RESTORE
36200 FOR ZL=1 TO CL:FOR ZD=0 TO 5
36250 READ DS(ZL,ZD):NEXT:NEXT
36300 DIM OB(LO,2)
36350 FOR ZL=1 TO LO:READ OB(ZL,0),OB(ZL,1),OB(ZL,2):NEXT ZL
36500 DIM HE$(CL)
36550 HE$(1)="I THINK WE'RE SUPPOSED TO LEAVE THE STUFF HERE
36650 HE$(7)="HOW ABOUT A BLASTER?
36660 HE$(2)="I WONDER IF WE HAVE ENOUGH FUEL?
36700 HE$(9)="TRY SHOOT GUARD?
36750 HE$(13)="IT MIGHT BE INTERESTING TO READ THE GRAFFITI
36800 HE$(17)="TRY SHOOT SCIENTIST?
36850 HE$(22)="I'M AS CONFUSED AS YOU ARE":HE$(29)=HE$(22)
36900 HE$(31)="IT MIGHT HELP IF WE HAD SOME KEYS TO OPEN ANY LOCKED DOORS
36950 HE$(35)="DID YOU BRING ANYTHING TO EAT?
37100 M0$="I CAN'T GO THERE. THE DOOR IS LOCKED.
37150 M1$="I'M NOT CARRYING ANY BLANK TAPE
37200 M2$="THE TRS-80 RECORDED SOMETHING ON THE TAPE, AND THEN IT PRINTED:"+CHR$(13)+CHR$(10)+"        >> ATTACK PLANS -- VERY SECRET <<
37250 M3$="I CAN'T. I'M NOT CARRYING ANY KEYS.
37300 M4$="O.K.  THE DO OR TO THE JAIL CELL IS UNLOCKED
37350 M5$="THERE'S NO ROBOT HERE
37400 M6$="BUT, I DON'T HAVE AND HAMBURGERS.
37450 M7$="CHUMP . . . CHUMP  BURP!!"+CHR$(13)+CHR$(10)+"THE PRINCESS THANKS YOU FOR A DELICIOUS MEAL
37500 M8$=" DOESN'T EAT HAMBURGER
37550 M9$="NOTHING HAPPENED. THE HAMBURGER IS COLD YOU KNOW
37600 N0$="THE ATTACK ROBOT EATS THE HAMBURGER AND DISAPPEARS.
37650 N1$="I'M AT THE IDENTIFICATION TERMINAL ON THE SCREEN IT SAYS: >> SHOW I.D. <<"
37700 N2$="THE TRACTOR BEAM IS OFF
37750 N3$="THE TRACTOR BEAM IS ON
37800 N4$="YOU FORGOT TO OPEN THE FLIGHT DECK DOORS	
37850 RETURN
HE TRACTOR BEAM IS OFF
37750 N3$="THE TRACTOR BEAM IS ON
3780