5 GOSUB 940
10 DIM SC$(20,60),DI(20,60)
20 GOSUB 830
25 PRINT CHR$(26)
30 FOR X=1 TO 20:FOR Y=1 TO 60:SC$(X,Y)=" ":NEXT Y:NEXT X
40 PRINT CHR$(26)CHR$(27)CHR$(46)CHR$(48)CHR$(27)CHR$(97);
50 FOR X=1 TO 62:PRINT"C";:NEXT X:PRINT
60 FOR X=1 TO 20:PRINT"C"SPC(60)"C":NEXT X
70 FOR X=1 TO 62:PRINT"C";:NEXT X:PRINT CHR$(30)
80 F(1)=10:F(2)=30:B(1)=11:B(2)=30:C$=CHR$(11):SC$(B(1),B(2))="T"
90 DI(10,30)=8:DI(11,30)=8:SC$(13,13)="V"
100 PRINT CHR$(27)"="CHR$(32+13)CHR$(32+13)"V"
110 PRINT CHR$(27)"="CHR$(32+F(1))CHR$(32+F(2))"U"
120 PRINT CHR$(27)"="CHR$(32+B(1))CHR$(32+B(2))"T"
130 A$=INKEY$
140 IF A$<>CHR$(11) AND A$<>CHR$(10) AND A$<>CHR$(8) AND A$<>CHR$(12) THEN A$=C$
150 IF A$=CHR$(11) AND C$=CHR$(10) THEN A$=C$
155 IF A$=CHR$(10) AND C$=CHR$(11) THEN A$=C$
160 IF A$=CHR$(8) AND C$=CHR$(12) THEN A$=C$
165 IF A$=CHR$(12) AND C$=CHR$(8) THEN A$=C$
170 IF A$=CHR$(11) THEN C$=A$:GOTO 210 ELSE IF A$=CHR$(8) THEN C$=A$:GOTO 290
180 IF A$=CHR$(10) THEN C$=A$:GOTO 340 ELSE IF A$=CHR$(12) THEN C$=A$:GOTO 390
190 IF T=0 THEN GOSUB 510 ELSE GOSUB 560
200 GOTO 130
210 IF F(1)=1 THEN 440
220 IF SC$(F(1)-1,F(2))="T" THEN 440
230 SC$(F(1),F(2))="T":DI(F(1),F(2))=8
240 PRINT CHR$(27)"="CHR$(32+F(1))CHR$(32+F(2))"T"
250 F(1)=F(1)-1
260 PRINT CHR$(27)"="CHR$(32+F(1))CHR$(32+F(2))"U"
270 IF SC$(F(1),F(2))="V" THEN SC$(F(1),F(2))=" ":T=0:PTS=PTS+50
280 GOTO 190
290 IF F(2)=1 THEN 440
300 IF SC$(F(1),F(2)-1)="T" THEN 440
310 SC$(F(1),F(2))="T":DI(F(1),F(2))=4
320 PRINT CHR$(27)"="CHR$(32+F(1))CHR$(32+F(2))"T"
330 F(2)=F(2)-1:GOTO 260
340 IF F(1)=20 THEN 440
350 IF SC$(F(1)+1,F(2))="T" THEN 440
360 SC$(F(1),F(2))="T":DI(F(1),F(2))=2
370 PRINT CHR$(27)"="CHR$(32+F(1))CHR$(32+F(2))"T"
380 F(1)=F(1)+1:GOTO 260
390 IF F(2)=60 THEN 440
400 IF SC$(F(1),F(2)+1)="T" THEN 440
410 SC$(F(1),F(2))="T":DI(F(1),F(2))=6
420 PRINT CHR$(27)"="CHR$(32+F(1))CHR$(32+F(2))"T"
430 F(2)=F(2)+1:GOTO 260
440 GOSUB 630
450 PRINT CHR$(26)CHR$(27)CHR$(46)CHR$(50)CHR$(27)CHR$(97)
460 PRINT:PRINT:PRINT:PRINT"YOU HAD"PTS"POINTS!!!"
470 PRINT"DO YOU WANT TO PLAY AGAIN? (Y/N) ";
480 A$=INPUT$(1)
490 IF A$="Y" THEN PRINT:RUN ELSE IF A$="N" THEN RUN"HELPER"
500 GOTO 480
510 K=INT(RND*18+2):L=INT(RND*58+2)
520 IF K=F(1) AND L=F(2) THEN 510
530 IF SC$(K,L)<>" " THEN 510
540 PRINT CHR$(27)"="CHR$(32+K)CHR$(32+L)"V"
550 SC$(K,L)="V":T=1:RETURN
560 PRINT CHR$(27)"="CHR$(32+B(1))CHR$(32+B(2))" "
570 SC$(B(1),B(2))=" "
580 IF DI(B(1),B(2))=8 THEN B(1)=B(1)-1:GOTO 620
590 IF DI(B(1),B(2))=4 THEN B(2)=B(2)-1:GOTO 620
600 IF DI(B(1),B(2))=2 THEN B(1)=B(1)+1:GOTO 620
610 IF DI(B(1),B(2))=6 THEN B(2)=B(2)+1:GOTO 620
620 RETURN
630 FOR X=1 TO 1000:NEXT
640 FOR X=1 TO 48:PRINT:NEXT
650 PRINT"TTTTTTTTT     TTTTTTTT    TTTTTTTT   TT      TT   TTT"
660 PRINT"TT      TT   TT      TT  TT      TT  TTT    TTT  TTTTT"
670 PRINT"TT      TT   TT      TT  TT      TT  TT T  T TT  TTTTT"
680 PRINT"TTTTTTTTT    TT      TT  TT      TT  TT  TT  TT  TTTTT"
690 PRINT"TT      TT   TT      TT  TT      TT  TT  TT  TT   TTT"
700 PRINT"TT      TT   TT      TT  TT      TT  TT      TT"
710 PRINT"TTTTTTTTT     TTTTTTTT    TTTTTTTT   TT      TT   TTT"
720 PRINT:PRINT:PRINT:PRINT:PRINT CHR$(27)CHR$(65)
730 FOR X=1 TO 1000:NEXT
740 PRINT CHR$(26)
750 PRINT"     WELL, I SEE YOU HAVE BLOWN UP.   YOU WERE RADIOACTIVE FROM"
760 PRINT"  GOBBLING BOMBS INCAPABLE OF DESTROYING A FLEA.   YOU MANAGED TO"
770 PRINT"  ESCAPE THE TIME LIMIT BY 0.16354 SECONDS.   GOOD, BUT NOT GOOD"
780 PRINT"  ENOUGH.   BECAUSE OF YOUR CLUMSINESS YOU WERE VERY UNFORTUNATELY"
790 PRINT"  DESTROYED BY A DISASTROUS EXPLOSION.   AND IT WAS YOUR FAULT!!!"
800 PRINT
810 PRINT"           P.S. YOUR GOVERNMENT SENDS ITS SINCEREST REGRETS.
820 GOTO 460
830 PRINT CHR$(26)CHR$(27)CHR$(46)CHR$(48)
840 PRINT:PRINT:PRINT:PRINT
850 PRINT"   WELCOME TO THE PLANET XERXES, WHICH ORBITS AROUND THE STAR S25J879."
860 PRINT" YOU ARE AGENT CENTIPEDE OF THE SPECIES SLIMIUS KRAWLATUMS.  YOUR
870 PRINT" GOVERNMENT HAS BEEN PLAGUED FOR YEARS BY INVISBLE SCORPIONS WHO HAVE"
880 PRINT" BEEN PLANTING BOMBS SET FOR DETONATION IN YOUR VICINITY.   YOUR"
890 PRINT" MISSION IS TO EAT ALL THE BOMBS BEFORE THEY GO OFF.   YOUR GOVERNMENT"
900 PRINT" IS DEPENDING ON YOU!        G O O D  L U C K !"
910 PRINT
920 PRINT"                           PRESS ANY KEY TO BEGIN":A$=INPUT$(1):PRINT
930 RETURN
940 FOR X=1 TO 48:PRINT:NEXT X:PRINT CHR$(27)CHR$(97)
950 PRINT"               TTTTTTTTT   TTTTTTTT   TTTTTTTTT"
960 PRINT"                    TTT   TTT    TTT  TTT    TTT"
970 PRINT"                   TTT    TTT    TTT  TTT    TTT"
980 PRINT"                  TTT     TTTTTTTTTT  TTTTTTTTT"
990 PRINT"                 TTT      TTT    TTT  TTT"
1000 PRINT"                TTT       TTT    TTT  TTT"
1010 PRINT"               TTTTTTTTT  TTT    TTT  TTT"
1015 PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT
1020 PRINT CHR$(27)CHR$(65)SPC(20)CHR$(147)" 1985  ZAP by John Pursey"
1030 FOR X=1 TO 2000:NEXT:FOR X=1 TO 24:PRINT:NEXT:RETURN
 PRINT CHR$(27)CHR$(65)SPC(20)CHR$(147)" 1985  ZAP by John Pursey"
1030 F