10 PRINT CHR$(26):PRINT
20 PRINT"   *************************************************"
30 PRINT"   *  PROPORTIONAL PRINTING WITH C ITOH PROWRITER  *"
40 PRINT"   *************************************************":PRINT
50 INPUT "   Was PIP with [Z] used on file to be printed? (Y/N)";Y$:PRINT
60 IF Y$ = "Y" OR Y$ = "y" THEN GOTO 210
70 IF Y$ = "N" OR Y$ = "n" THEN GOTO 80 ELSE 50
80 PRINT:PRINT "    Return to CP/M and PIP file with [Z] parameter  as follows:":PRINT
90 PRINT "         PIP D:NEWFILEN.AME = D:OLDFILEN.AME[Z] <CR>":PRINT
100 PRINT"    To return to CP/M, on Ok prompt type SYSTEM <CR>":PRINT
105 PRINT"    To return to program, on Ok prompt type RUN <CR>":PRINT
110 GOTO 7040
210	DATA 19,26,111,19,26,103,94,14,5,195,5,0
220	RESTORE 210
230	FOR I = 0 TO 11
240    	    READ XX
250	    POKE &H40+I,XX
260	NEXT I
270	DEF USR 0 = &H40
280	GOTO 2890
450	FOR III = 1 TO LEN(D$)
460	    C$ = MID$(D$,III,1)
470	    IF GRAPHFLAG = 1 THEN GOTO 580
480	    IF ASC(C$) < &H20 THEN GOTO 640
490	    IF STRIKEFLAG = 1 THEN GOTO 1770
510	    Z$ = USR 0 (C$)
520	    IF INTFLAG > 0 THEN GOTO 1850
540	NEXT III
550	RETURN
580	IF C$ = "Z" THEN GRAPHFLAG = 0 : GOTO 540
590	C$ = CHR$(ASC(C$) + 128)
600	GOTO 510
640	ON ASC(C$) GOTO 790, 820, 920, 840, 1020, 1050
660	ON ASC(C$)-6 GOTO 540, 1110, 540, 510, 540
680	ON ASC(C$)-11 GOTO 540, 510, 1150, 1050, 540
700	ON ASC(C$)-16 GOTO 1180, 1210, 1240, 1340, 540
720	ON ASC(C$)-21 GOTO 1500, 1670, 1740, 540, 540
740	IF ASC(C$) = &H1B THEN GOTO 510
745	IF ASC(C$) = &H1F THEN C$ = "-" : GOTO 510
760	GOTO 540
790	PITMEM$ = "E" : CON$ = "E"+CHR$(&H1B) : GOTO 1810 
820	GOTO 840
840	BOLDFLAG = (BOLDFLAG + 1) MOD 2
850	IF BOLDFLAG = 0 THEN GOTO 880
860	BLDMEM$ = "!" : CON$ = "!"+CHR$(&H1B) : GOTO 1810
880	BLDMEM$ = CHR$(&H22)
890	CON$ = CHR$(&H22)+CHR$(&H1B) : GOTO 1810
920	PRINT "A Control C in the text has stopped the print"
930	PRINT "Press any key to resume" + CHR$(7)
940	ISTOP = 0
960	CON$ = INKEY$ : ISTOP = ISTOP + 1
970	IF ISTOP > 150 THEN PRINT CHR$(7) : ISTOP = 0
980	IF CON$ = "" GOTO 960
990	GOTO 540
1020	GRAPHFLAG = 1: GOTO 540
1050	IF PITCH <> 0 THEN GOTO 1080
1060	CON$ = "6"+CHR$(27)+"6"+CHR$(27) : GOTO 1810
1080	C$ = " " : GOTO 510
1110	CON$ = "]"+CHR$(&H1B)+CHR$(8)+"["+CHR$(&H1B)
1120	GOTO 1810
1150	PITMEM$ = "P" : CON$ = "P"+CHR$(&H1B) : GOTO 1810
1180	PITMEM$ = "Q" : CON$ ="Q"+CHR$(&H1B) : GOTO 1810
1210	PITMEM$ = "N" : CON$ = "N"+CHR$(&H1B) : GOTO 1810
1240	UNDERFLAG = (UNDERFLAG + 1) MOD 2
1250	IF UNDERFLAG = 0 GOTO 1280
1260	CON$ = "X"+CHR$(&H1B) : GOTO 1810 
1280	CON$ = "Y"+CHR$(&H1B) : GOTO 1810
1340	SUPERFLAG = (SUPERFLAG +1) MOD 2
1350	IF SUPERFLAG = 0 GOTO 1430
1360	C$ = RIGHT$(STR$(SR),2)
1370	IF MID$(C$,1,1) = " " THEN MID$(C$,1,1) = "0"
1380	C$ = RIGHT$(C$,1) + LEFT$(C$,1)
1390	CON$ = "r"+CHR$(27)+"["+CHR$(27)
1400	CON$ = "f"+CHR$(27)+CHR$(10)+C$+"T"+CHR$(27)+CON$
1410	GOTO 1810
1430	C$ = RIGHT$(STR$(LH),2)
1440	IF MID$(C$,1,1) =" " THEN MID$(C$,1,1) = "0"
1450	CON$ = RIGHT$(C$,1)+LEFT$(C$,1)
1460	CON$ = "]"+CHR$(27)+CON$+"T"+CHR$(27)+CHR$(10)
1470	GOTO 1810
1500	SUBFLAG = (SUBFLAG + 1) MOD 2
1510	IF SUBFLAG = 0 GOTO 1590
1520	C$ = RIGHT$(STR$(SR),2)
1530	IF MID$(C$,1,1) =" " THEN MID$(C$,1,1) = "0"
1540	C$ = RIGHT$(C$,1) + LEFT$(C$,1)
1550	CON$ = "f"+CHR$(27)+"["+CHR$(27) 
1560	CON$ = "r"+CHR$(27)+CHR$(10)+C$+"T"+CHR$(27)+CON$
1570	GOTO 1810
1590	C$ = RIGHT$(STR$(LH),2)
1600	IF MID$(C$,1,1) = " " THEN MID$(C$,1,1) = "0"
1610	CON$ = RIGHT$(C$,1)+LEFT$(C$,1)
1620	CON$ = "]"+CHR$(27)+"f"+CHR$(27)+CON$
1630	CON$ = CON$ +"T"+CHR$(27)+CHR$(10)
1640	GOTO 1810
1670	WIDEFLAG = (WIDEFLAG + 1) MOD 2
1680	IF WIDEFLAG = 0 GOTO 1710
1690	C$ = CHR$(&HE) : GOTO 510
1710	C$ = CHR$(&HF) : GOTO 510
1740	STRIKEFLAG = (STRIKEFLAG + 1) MOD 2
1750	GOTO 540
1770	CON$ = "-"+"]"+CHR$(&H1B)+CHR$(8)+C$+"["+CHR$(&H1B)
1780	GOTO 1810
1810	INTFLAG = LEN(CON$) - 1
1820	C$ = RIGHT$(CON$,1) : GOTO 510
1850	C$ = MID$(CON$,INTFLAG,1)
1860	INTFLAG = INTFLAG - 1 : GOTO 510
1920	IZ = INSTR(FIRSTCOL,FILLIN$,"  ")
1930	IF IZ <> 0 THEN GOTO 1960
1940	RETURN
1960	RGTPART$ = RIGHT$(FILLIN$,LEN(FILLIN$)-IZ-1)
1970	FILLIN$ = LEFT$(FILLIN$,IZ)+RGTPART$
1980	GOTO 1920
2050	IZ = LEN(FILLIN$)
2080	IF IZ = 0 THEN IZ = 1 : GOTO 2130
2090	IF MID$(FILLIN$,IZ,1) <> " " GOTO 2130
2100	IZ = IZ - 1 : GOTO 2080
2130	FILLIN$ = LEFT$(FILLIN$,IZ)
2140	IF IZ = 1 THEN GOTO 2220
2150	IZ = 1
2180	IF MID$(FILLIN$,IZ,1) <> " " GOTO 2220
2190	    IZ = IZ + 1 : GOTO 2180
2220	FIRSTCOL = IZ
2230	IF MID$(FILLIN$,IZ,1) = CHR$(15) THEN GOTO 2260
2240	GOSUB 1920
2260	LASTCOL = LEN(FILLIN$) : RETURN
2320	DOTSUM = 0
2330	ENDINDEX = LASTCOL
2340	IF LASTCOL < LEN(FILLIN$) THEN ENDINDEX = LEN(FILLIN$)
2350	FOR IZ = FIRSTCOL TO ENDINDEX
2360	    IF IZ > LEN(FILLIN$) THEN GOTO 2630
2370	    DOTIND = ASC(MID$(FILLIN$,IZ,1))-&H20
2380	    IF DOTIND < 0 THEN GOTO 2470	
2390	    IF PITCH <> 0 THEN GOTO 2430	
2400	    DOTSUM = DOTSUM + DOTS(DOTIND)*SIZE
2410	    GOTO 2600
2430	    DOTSUM = DOTSUM + PITCH*SIZE
2440	    GOTO 2600
2470        IF DOTIND <> 8 - 32 THEN GOTO 2530	
2490	    IZ = IZ +1
2500	    IF MID$(FILLIN$,IZ,1) < CHR$(&H20) THEN GOTO 2490
2510	    GOTO 2600
2530	    IF DOTIND=1-32 THEN PITCH =13.3333 : GOTO 2600
2540	    IF DOTIND=14-32 THEN PITCH=0 : GOTO 2600
2550	    IF DOTIND=17-32 THEN PITCH=9.41177 : GOTO 2600
2560	    IF DOTIND=18-32 THEN PITCH=16 : GOTO 2600
2570	    IF DOTIND=23-32 THEN SIZE = (SIZE MOD 2) + 1
2580	    IF DOTIND=15-32 THEN DOTSUM = DOTSUM + 12
2600	NEXT IZ
2630	DOTSUM = INT(DOTSUM +.5) : RETURN
2750	DATA  7 , 7 , 10 , 14 , 12 , 16 , 13 , 7
2760	DATA  7 , 7 , 12 , 12 , 7 , 12 , 7 , 12
2770	DATA  12 , 12 , 12 , 12 , 12 , 12 , 12 , 12
2780	DATA  12 , 12 , 7 , 7 , 12 , 12 , 12 , 12
2790	DATA  14 , 16 , 15 , 14 , 15 , 15 , 15 , 14
2800	DATA  15 , 9 , 13 , 12 , 13 , 17 , 16 , 15
2810	DATA  13 , 16 , 15 , 12 , 14 , 15 , 16 , 17
2820	DATA  11 , 14 , 11 , 12 , 12 , 12 , 12 , 12
2830	DATA  7 , 12 , 12 , 10 , 12 , 12 , 10 , 12
2840	DATA  12 , 8 , 7 , 10 , 8 , 16 , 12 , 12
2850	DATA  12 , 12 , 10 , 12 , 10 , 12 , 12 , 16
2860	DATA  12 , 12 , 10 , 10 , 7 , 10 , 12 , 0
2890	DIM DOTS(95)
2940	RESTORE 2750
2950	FOR I = 0 TO 95
2960	    READ DOTS(I)
2970	NEXT I
3010	INPUT "Enter name of file to print"; FILENAME$
3020	OPEN "I",1,FILENAME$
3040 PRINT CHR$(26)
3050 PRINT "               PRINTING ";FILENAME$:PRINT
3060	D$ = CHR$(&H1B) + "P"
3070	GOSUB 450
3100	LH = 24 : PL = 66 : MT = 3 : MB = 8 : HM = 2 : FM = 2
3110	OP = 8 : PN = 1 : SR = 9 : POFF = 30
3120	PAGEFLAG = 1 : HEADERFLAG = 0
3130	FOOTERFLAG = 0 : JUSTFLAG = 1
3140	SIZE = 1 : PITCH = 0 : PLENGTH = 1584 : PLINES = 0
3150	PITMEM$ = "P" : BLDMEM$ = CHR$(&H22)
3180	GOTO 4880
3250	CONRET = 0
3260	DOTSPEC$ = MID$(FILLIN$,2,2)
3270	IF DOTSPEC$ = "PA" THEN CONRET = 1 : RETURN
3280	IF DOTSPEC$ = "CP" THEN GOTO 3580
3290	IF DOTSPEC$ = ".C" THEN GOTO 3640
3300	IF DOTSPEC$ = "HE" THEN GOTO 3730
3310	IF DOTSPEC$ = "FO" THEN GOTO 3840
3320	IF DOTSPEC$ = "OP" THEN PAGEFLAG = 0 : RETURN
3330	IF DOTSPEC$ = "LH" THEN GOTO 4230
3340	IF DOTSPEC$ = "PL" THEN GOTO 4370
3350	IF DOTSPEC$ = "MT" THEN GOTO 4430
3360	IF DOTSPEC$ = "MB" THEN GOTO 4480
3370	IF DOTSPEC$ = "HM" THEN GOTO 4530
3380	IF DOTSPEC$ = "FM" THEN GOTO 4580
3390	IF DOTSPEC$ = "PO" THEN GOTO 4710
3400	IF DOTSPEC$ = ".T" THEN GOTO 3950
3410	IF DOTSPEC$ = ".P" THEN GOTO 4070
3420	IF DOTSPEC$ = ".S" THEN GOTO 4120
3430	IF DOTSPEC$ = "UJ" THEN GOTO 4630
3440	IF DOTSPEC$ = "SR" THEN GOTO 4330
3450	IF DOTSPEC$ = "PN" THEN GOTO 4020
3460	IF DOTSPEC$ = ".." THEN RETURN
3470	PRINT  "UNRECOGNIZED DOT-COMMAND": RETURN
3510	SPECNUM = 0
3520	IF LEN(FILLIN$) < 4 THEN RETURN
3530	SPECNUM = VAL(MID$(FILLIN$,4,2))
3540	RETURN	
3580	GOSUB 3510
3590	IF PL - MB - LINENUMBER >= SPECNUM THEN RETURN
3600	CONRET = 1 : RETURN
3640	GOSUB 3510
3650	COLUMNS = SPECNUM
3670	IF COLUMNS < 1 THEN COLUMNS = 1
3680	IF COLUMNS > 3 THEN COLUMNS = 3
3690	RETURN
3730	I = LEN(FILLIN$)-3
3740	IF I < 1 THEN RETURN
3750	HEADERFLAG = 1
3760	HEADER$ = RIGHT$(FILLIN$,I) + CHR$(&HD) + CHR$(&HA)
3770	HDRK = INSTR(1,HEADER$,CHR$(11))
3780	HDRN = INSTR(1,HEADER$,"#")
3790	IF HDRK <> 0 THEN MID$(HEADER$,HDRK,1) = " "
3800	IF HDRN <> 0 THEN MID$(HEADER$,HDRN,1) = " "
3810	RETURN
3840	I = LEN(FILLIN$) - 3
3850	IF I < 1 THEN RETURN
3860	FOOTERFLAG = 1
3870	FOOTER$ = RIGHT$(FILLIN$,I) + CHR$(&HD) + CHR$(&HA)
3880	FTRK = INSTR(1,FOOTER$,CHR$(11))
3890	FTRN = INSTR(1,FOOTER$,"#")
3900	IF FTRK <> 0 THEN MID$(FOOTER$,FTRK,1) = " "
3910	IF FTRN <> 0 THEN MID$(FOOTER$,FTRN,1) = " "
3920	RETURN
3950	TITLEFLAG = 1
3960	I = LEN(FILLIN$) - 3
3970	IF I < 1 THEN RETURN
3980	TITLE$ = RIGHT$(FILLIN$,I)+CHR$(&HD)+CHR$(&HA)
3990	RETURN
4020	GOSUB 3510
4030	PN = SPECNUM : RETURN
4070	PLENGTH = VAL(MID$(FILLIN$,4,4))
4080	RETURN
4120	FILLIN$ = RIGHT$(FILLIN$,LEN(FILLIN$)-3)
4130	GOSUB 2050
4140	GOSUB 2320
4150	DOTSAMPLE = DOTSUM
4160	GOSUB 4750
4170	FILLIN$ = "." + FILLIN$
4180	RETURN
4230	GOSUB 3510
4240	IF SPECNUM > 99 THEN SPECNUM = 99
4250	LH = SPECNUM
4260	D$ = RIGHT$(STR$(LH),2)
4270	IF MID$(D$,1,1) = " " THEN MID$(D$,1) = 0
4280	D$ = CHR$(&H1B)+"T"+D$
4290	GOSUB 450
4300	RETURN
4330	GOSUB 3510
4340	SR = SPECNUM : RETURN
4370	GOSUB 3510
4380	PL = SPECNUM
4390	RETURN
4430	GOSUB 3510
4440	MT = SPECNUM
4450	RETURN
4480	GOSUB 3510
4490	MB = SPECNUM
4500	RETURN
4530	GOSUB 3510
4540	HM = SPECNUM
4550	RETURN
4580	GOSUB 3510
4590	FM = SPECNUM
4600	RETURN
4630	GOSUB 3510
4640	JUSTFLAG = SPECNUM
4650	RETURN
4710	GOSUB 3510
4720	POFF = (SPECNUM - 8)*16 + 30
4750	OFFSET = INT((1280 - DOTSAMPLE)/2) + POFF
4760	OFFS$ = STR$(OFFSET)
4770	IF MID$(OFFS$,1,1) = " " THEN MID$(OFFS$,1,1) = "0"
4780	IF MID$(OFFS$,2,1) = " " THEN MID$(OFFS$,2,1) = "0"
4790	OFFS$ = CHR$(&H1B)+"F"+RIGHT$("000"+OFFS$,4)
4800	RETURN
4880	LINE INPUT#1,FILLIN$
4890	IF LEN(FILLIN$) < 3 THEN GOTO 4920
4900	IF MID$(FILLIN$,2,2) = ".S" THEN GOTO 5130
4920	DOTSAMPLE = 0
4930	FOR I = 1 TO 20
4950	    LINE INPUT#1,FILLIN$
4960	    IF LEN(FILLIN$) = 0 THEN GOTO 4950
4970	    IF ASC(FILLIN$) = ASC(".") THEN GOTO 4950
4980	    GOSUB 2050
4990	    GOSUB 2320
5000	    IF DOTSUM > DOTSAMPLE THEN DOTSAMPLE = DOTSUM
5020	NEXT I
5050	DOTSAMPLE = DOTSAMPLE + 40
5080	GOSUB 4750
5130	CLOSE
5140	OPEN "I",1,FILENAME$ : ON ERROR GOTO 7030
5150	GOTO 5640
5180	CONRET = 0
5190	FOR IY = 1 TO PL-MB-LINENUMBER
5200	    LPRINT
5210	    LINENUMBER = LINENUMBER + 1 : PLINES = PLINES + LH
5220	NEXT IY
5250	IF FOOTERFLAG = 0 THEN GOTO 5440
5260	FOR I = 1 TO FM
5270	    LPRINT
5280	NEXT I
5290	IF FTRK > 2 THEN MID$(FOOTER$,FTRK-2,3) = "   "
5300	IF FTRN > 2 THEN MID$(FOOTER$,FTRN-2,3) = "   "
5310	IZ = FTRK
5320	IF (FTRK <> 0) AND ((PN MOD 2) = 0) THEN GOTO 5360
5330	IF FTRN = 0 THEN GOTO 5390
5340	IZ = FTRN
5360	PNUM$=STR$(PN) : PNUMLEN = LEN(PNUM$)
5370	MID$(FOOTER,IZ-PNUMLEN+1,PNUMLEN) = PNUM$
5390	RESTOR$ = CHR$(27)+BLDMEM$+CHR$(27)+PITMEM$
5400	D$ = OFFS$ + FOOTER$ + RESTOR$ : GOSUB 450
5410	PLINES = PLINES + LH
5440	PN = PN + 1
5450	RMA144 = PLENGTH - (PLINES MOD PLENGTH)
5460	NUMBERLF = INT(RMA144/LH)
5470	IF NUMBERLF < 1 THEN GOTO 5530
5480	FOR I = 1 TO NUMBERLF
5490	    LPRINT
5500	    RMA144 = RMA144 - LH
5510	NEXT I
5530	IF RMA144 = 0 THEN GOTO 5640
5540	D$ = RIGHT$(STR$(RMA144),2)
5550	IF MID$(D$,1,1) = " " THEN MID$(D$,1,1) ="0"
5560	D$ = CHR$(27)+"T"+D$+CHR$(13)+CHR$(10) : GOSUB 450
5570	D$ = RIGHT$(STR$(LH),2)
5580	IF MID$(D$,1,1) = " " THEN MID$(D$,1,1) = "0"
5590	D$ = CHR$(27)+"T"+D$ : GOSUB 450
5640	LINENUMBER = 1 : PLINES = 0
5650	LINE INPUT#1, FILLIN$
5660	PRINT FILLIN$
5670	IF LEN(FILLIN$) = 0 THEN GOTO 5760
5680	IF ASC(FILLIN$) <> ASC(".") THEN GOTO 5760 
5690	GOSUB 3250
5700	IF CONRET = 1 THEN GOTO 5180
5710	GOTO 5640
5760	IF MT - HM < LINENUMBER THEN GOTO 5850
5770	LPRINT
5780	LINENUMBER = LINENUMBER + 1
5790	PLINES = PLINES + LH
5800	GOTO 5760
5850	IF PN <> 1 GOTO 5930
5860	IF TITLEFLAG = 0 GOTO 5930
5870	D$ = TITLE$ : GOSUB 450
5880	LINENUMBER = LINENUMBER + 1
5890	PLINES = PLINES + LH
5900	GOTO 6100
5930	IF HEADERFLAG = 0 THEN GOTO 6100
5940	IF HDRK > 2 THEN MID$(HEADER$,HDRK-2,3) = "   "
5950	IF HDRN > 2 THEN MID$(HEADER$,HDRN-2,3) = "   "
5960	IZ = HDRK
5970	IF (HDRK <> 0) AND ((PN MOD 2) = 0) THEN GOTO 6010
5980	IF HDRN = 0 THEN GOTO 6040
5990	IZ = HDRN
6010	PNUM$ = STR$(PN) : PNUMLEN = LEN(PNUM$)
6020	MID$(HEADER$,IZ-PNUMLEN+1,PNUMLEN) = PNUM$
6040	RESTOR$ = CHR$(27)+BLDMEM$+CHR$(27)+PITMEM$
6050	D$ = OFFS$+HEADER$ + RESTOR$ : GOSUB 450
6060	LINENUMBER = LINENUMBER + 1
6070	PLINES = PLINES + LH
6100	IF LINENUMBER > MT THEN GOTO 6210
6110	LPRINT
6120	LINENUMBER = LINENUMBER + 1
6130	PLINES = PLINES + LH
6140	GOTO 6100
6180	LINE INPUT #1, FILLIN$
6190	PRINT FILLIN$
6210	IF PAGEFLAG = 0 THEN GOTO 6340
6220	IF LEN(FILLIN$) = 0 THEN GOTO 6180
6230	GOTO 6340
6280	IF PAGEFLAG = 0 THEN GOTO 6310
6290	IF LINENUMBER > (PL - MB) THEN GOTO 5250
6310	LINE INPUT #1, FILLIN$
6320	PRINT FILLIN$
6340	IF LEN(FILLIN$) = 0 THEN GOTO 6400
6350	IF ASC(FILLIN$) = ASC(".") THEN GOSUB 3250
6360	IF CONRET = 1 THEN GOTO 5180
6370	IF ASC(FILLIN$) = ASC(".") THEN GOTO 6280
6380	IF JUSTFLAG <> 0 THEN GOTO 6480
6400	D$ = FILLIN$+CHR$(&HD)+CHR$(&HA)
6410	GOSUB 450
6420	LINENUMBER = LINENUMBER + 1
6430	PLINES = PLINES + LH
6440	GOTO 6280
6480	GOSUB 2050
6490	GOSUB 2320
6500	ADJDOTS = DOTSAMPLE-DOTSUM
6510	IF ADJDOTS < 0 THEN GOTO 6400
6540	NUMSPACE = 0
6550	FOR I = FIRSTCOL TO LASTCOL
6560	    IF MID$(FILLIN$,I,1) <> " " THEN GOTO 6590
6570	    NUMSPACE = NUMSPACE + 1
6590	NEXT I
6630	IF NUMSPACE = 0 THEN  GOTO 6710
6640	ADDDOTS	= 1 + INT(ADJDOTS/NUMSPACE)
6670	IF ADDDOTS > 36 THEN ADDDOTS = 12
6710	D$ = OFFS$
6720	GOSUB 450
6730	FOR I = FIRSTCOL TO LASTCOL
6740	    D$ = MID$(FILLIN$,I,1)
6750	    IF D$ <> " " THEN GOTO 6940
6760		IF ADJDOTS = 0 THEN GOTO 6940
6770		IF ADJDOTS < ADDDOTS THEN ADDDOTS = ADJDOTS
6780		ADJDOTS = ADJDOTS - ADDDOTS
6790		NOWDOTS = ADDDOTS
6810		IF NOWDOTS > 6 THEN GOTO 6860
6820		D$ = CHR$(&H1B)+CHR$(NOWDOTS+48)
6830		GOSUB 450
6840		GOTO 6920
6860		D$ = CHR$(&H1B)+"6"
6870		GOSUB 450
6880		NOWDOTS = NOWDOTS - 6
6890		IF NOWDOTS = 0 THEN GOTO 6920
6900		GOTO 6810
6920	    D$ = " "
6940	    GOSUB 450
6950	NEXT I
6960	D$ = CHR$(&HD) + CHR$(&HA)
6970	GOSUB 450
6980	LINENUMBER = LINENUMBER + 1
6990	PLINES = PLINES + LH
7000	GOTO 6280
7030	CLOSE
7040	END
 CHR$(&HA)
6970	GOSUB 450
6980	LINENUMBER = LINENUMBER + 1
6990	PLINES = PLINES + LH
7000	GOTO