1 REM Revised for Osborne 1 by Jim Woolley, FOG Librarian, 7/82
2 REM Further revised for 52 column screen and
3 REM prompting enhancements by Carl Tenning 10/84
5 RANDOMIZE
10 PRINT CHR$(26)
20 DIM G$(10), G(10)
30 G$(0)="THE NUMBER IS BLACK"
35 G$(1)="THE NUMBER IS RED"
40 G$(2)="AND THE NUMBER IS"
45 G$(3)="THE NUMBER COMES UP"
50 G$(4)="THE MAGIC NUMBER IS"
55 G$(5)="THE BALL COMES TO REST ON"
60 G$(6)="AND THE NUMBER COMES UP ---------------"
65 G$(7)="AND THIS TIME IT'S --------------------"
70 G$(8)="AND THE NUMBER IS ---------------------"
75 G$(9)="THE MARBLE FALLS AND BOUNCES ON -------"
80 G$(10)="WELL THE NUMBER CAME UP --------------"
100 LET P=5000
110 PRINT "THIS PROGRAM IS DESIGNED TO SIMULATE THE FRENCH"
120 PRINT "GAMBLING GAME OF ROULETTE."
130 PRINT:PRINT:PRINT
150 PRINT "DO YOU WISH TO SEE A DESCRIPTION OF THE RULES"
160 INPUT A$ 
170 IF LEFT$(A$,1)<>"Y" AND LEFT$(A$,1)<>"y" THEN 500
180 PRINT "YOU BEGIN WITH $5,000 AND MAY BET AS MUCH AS YOU"
190 PRINT "LIKE UNTIL YOU HAVE EITHER WON $100,000 OR YOU"
200 PRINT "GO BROKE, WHICHEVER COMES FIRST.  THE BETTING IS"
210 PRINT "DONE ON A BOARD OR CLOTH SUCH AS APPEARS BELOW."
220 PRINT "HALF THE NUMBERS ARE RED AND HALF ARE BLACK EXCEPT"
230 PRINT "ZERO WHICH IS COLORLESS. BETTING COMBINATIONS AND"
240 PRINT "ODDS ARE AS FOLLOWS:"
250 PRINT
260 GOSUB 2000
270 PRINT
280 PRINT "Hit any key to continue"; : NN$=INPUT$(1)
400 PRINT CHR$(26)
410 PRINT   
420 PRINT "WHEN ASKED TO PLACE YOUR BET, DO SO BY FIRST"
430 PRINT "INPUTING THE AMOUNT OF THE BET (SMALLEST BET =$1.00)"
440 PRINT "AND THE NUMBER OF THE TYPE OF BET DESIRED FROM THE"
450 PRINT "TABLE ABOVE. HERE IS THE ROULETTE LAYOUT:"
460 PRINT
470 GOSUB 3000
480 PRINT
490 PRINT "Hit any key to continue" : NN$=INPUT$(1)
500 PRINT CHR$(26)
620 PRINT "THE ROULETTE WHEEL IS SPINNING-ROUND AND ROUND IT"   
630 PRINT "GOES, WHERE SHE STOPS NOBODY KNOWS." 
640 LET X=0 
650 GOSUB 2000 : LET Y=INT(37*RND(1))
655 PRINT
660 PRINT "FAITES VOS JEUX MESSIEUR (PLACE YOUR BETS GENTLEMEN)"
670 INPUT "(amount, type)";B,C   
680 ON C GOTO 770,890,990,1090,1280,1430,1490,1560,1640,1730
690 PRINT CHR$(26)
700 GOTO 620
770 LET E=1 
780 PRINT "WHICH COLOR DO YOU WANT TO BET ON"   
790 INPUT "(R or B)";Z$
800 IF Y=0 THEN 1880
810 IF Y<19 THEN 860
820 NN=0
830 IF LEFT$(Z$,1)="B" OR LEFT$(Z$,1)="b" THEN 1820
840 GOTO 1880  
850 PRINT   
860 NN=1
870 IF LEFT$(Z$,1)="R" OR LEFT$(Z$,1)="r" THEN 1820
880 GOTO 1880  
890 LET E=1 
900 PRINT "WHICH DO WANT TO BET ON, ODD OR EVEN"
910 INPUT "(O or E)";D$
920 NN=2
930 LET D1=Y/2  
940 IF D1=INT(Y/2) THEN 970 
950 IF LEFT$(D$,1)="O" OR LEFT$(D$,1)="o" THEN 1820
960 GOTO 1880  
970 IF LEFT$(D$,1)="E" OR LEFT$(D$,1)="e" THEN 1820
980 GOTO 1880  
990 LET E=1 
1000 PRINT "DO YOU BET HIGH (19-36) OR LOW (1-18)"   
1010 INPUT "(H or L)";H$
1020 NN=3
1030 IF Y=0 THEN 1880
1040 IF Y>18 THEN 1070
1050 IF LEFT$(H$,1)="L" OR LEFT$(H$,1)="l" THEN 1820
1060 GOTO 1880  
1070 IF LEFT$(H$,1)="H" OR LEFT$(H$,1)="h" THEN 1820
1080 GOTO 1880  
1090 LET E=2 
1100 PRINT "WHICH COLUMN DO YOU CHOOSE, 1,2,OR 3"
1105 GOSUB 3000
1110 INPUT "(1,2, or 3)";F 
1120 NN=4
1130 IF Y=0 THEN 1880
1140 IF F=2 THEN 1200 
1150 IF F=3 THEN 1240 
1160 FOR F1=1 TO 34 STEP 3 
1170 IF F1=Y THEN 1820   
1180 NEXT F1 
1190 GOTO 1880  
1200 FOR F1=2 TO 35 STEP 3 
1210 IF F1=Y THEN 1820   
1220 NEXT F1 
1230 GOTO 1880  
1240 FOR F1=3 TO 36 STEP 3 
1250 IF F1=Y THEN 1820   
1260 NEXT F1 
1270 GOTO 1880  
1280 LET E=2 
1290 PRINT "WHICH DOZEN NUMBERS DO YOU CHOOSE, LOW (1-12),"
1300 PRINT "MIDDLE (13-24), OR HIGH (25-36)"
1310 INPUT "(L,M, or H)";I$
1315 NN=5
1320 IF LEFT$(I$,1)="M" OR LEFT$(I$,1)="m" THEN 1380
1330 IF LEFT$(I$,1)="H" OR LEFT$(I$,1)="h" THEN 1410
1340 IF LEFT$(I$,1)<>"L" AND LEFT$(I$,1)<>"l" THEN 1290
1350 IF Y=0 THEN 1880
1360 IF Y<13 THEN 1820   
1370 GOTO 1880  
1380 IF Y>25 THEN 1880   
1390 IF Y<13 THEN 1880   
1400 GOTO 1820  
1410 IF Y>24 THEN 1820   
1420 GOTO 1880  
1430 LET E=36
1440 PRINT "OH OH, A LONG SHOT....PICK YOUR NUMBER." 
1450 INPUT G 
1460 NN=6
1470 IF G=Y THEN 1820
1480 GOTO 1880  
1490 LET E=17
1500 PRINT "WHAT TWO ADJACENT NUMBERS ARE YOU BETTING ON?"
1505 GOSUB 3000
1510 INPUT "(Input 2 numbers)";G1,G2 
1520 NN=7
1530 IF G1=Y THEN 1820   
1540 IF G2=Y THEN 1820   
1550 GOTO 1880  
1560 LET E=11   
1570 PRINT "WHAT THREE NUMBERS(RUNNING ACCROSS THE BOARD)"
1571 PRINT "DO YOU WANT?"
1575 GOSUB 3000
1580 INPUT "Input 3 numbers";G1,G2,G3 
1590 NN=8
1600 IF G1=Y THEN 1820  
1610 IF G2=Y THEN 1820  
1620 IF G3=Y THEN 1820  
1630 GOTO 1880 
1640 LET E=8
1650 PRINT "WHAT FOUR NUMBERS( IN A SQUARE ) DO YOU WANT?"
1655 GOSUB 3000
1660 INPUT "Input 4 numbers";G(1),G(2),G(3),G(4)  
1670 NN=9
1690 FOR I=1 TO 4 
1700 IF G(I)=Y THEN 1820
1710 NEXT I 
1720 GOTO 1880 
1730 LET E=5
1740 PRINT "WHAT SIX NUMBERS (IN A RECTANGLE ON THE BOARD)"
1750 PRINT "DO YOU WANT TO BET ON?"
1755 GOSUB 3000
1760 INPUT "Input 6 numbers";G(1),G(2),G(3),G(4),G(5),G(6)
1770 NN=10
1780 FOR I=1 TO 6 
1790 IF G(I)=Y THEN 1820
1800 NEXT I 
1810 GOTO 1880 
1820 PRINT CHR$(26);G$(NN);Y
1825 PRINT " *****A WINNER*****"
1830 PRINT "YOU WIN $"E*B   
1840 LET P=P+(E*B)  
1850 PRINT "YOUR PURSE NOW TOTALS $"P   
1860 IF P>100000! THEN 1930  
1870 GOTO 620  
1880 PRINT CHR$(26);G$(NN);Y
1885 PRINT " *****YOU LOSE*****"
1890 LET P=P-B  
1900 PRINT "YOUR PURSE NOW TOTALS $"P   
1910 IF P>0 THEN 620
1920 IF P=<0 THEN 1950  
1930 PRINT "END OF GAME. YOU BROKE THE HOUSE."
1940 GOTO 1960 
1950 PRINT "##### YOU'RE BROKE!!!!!"   
1960 END
2000 PRINT "****************************************************"   
2010 PRINT "          BET                          BANK PAYS" 
2020 PRINT "     -------------         -------------------------"  
2030 PRINT " 1.RED OR BLACK             EVEN MONEY (AMT OF BET)"  
2040 PRINT " 2.EVEN OR ODD              EVEN MONEY"  
2050 PRINT " 3.HIGH OR LOW              EVEN MONEY"  
2060 PRINT " 4.COLUMN 1,2,OR 3          2 TO 1"  
2070 PRINT " 5.DOZEN (LOW,MIDDLE,HIGH)  2 TO 1"  
2080 PRINT " 6.SINGLE NUMBERS 0-36      36 TO 1" 
2090 PRINT " 7.TWO NUMBERS(ADJACENT)    17 TO 1" 
2100 PRINT " 8.THREE NUMBERS ACROSS     11 TO 1" 
2110 PRINT " 9.FOUR NUMBERS (SQUARE)    8 TO 1"  
2120 PRINT "10.SIX NUMBERS(RECTANGLE)   5 TO 1"  
2130 PRINT "****************************************************"
2140 RETURN
3000 PRINT "              ***********************"   
3010 PRINT "              *         0           *"   
3020 PRINT "              *   1     2      3    *"   
3030 PRINT "              *   4     5      6    *"   
3040 PRINT "              *   7     8      9    *"   
3050 PRINT "              *  10    11     12    *"   
3060 PRINT "              *  13    14     15    *"   
3070 PRINT "              *  16    17     18    *"   
3080 PRINT "              *  19    20     21    *"   
3090 PRINT "              *  22    23     24    *"   
3100 PRINT "              *  25    26     27    *"   
3110 PRINT "              *  28    29     30    *"   
3120 PRINT "              *  31    32     33    *"   
3130 PRINT "              *  34    35     36    *"   
3140 PRINT "              ***********************"   
3150 PRINT "              ***********************"   
3160 RETURN
  
3140 PRINT "     