10 REM EL CHEAPO HOSTCM SUPPORT PACKAGE (Bob Scott July 83)
20 REM OPERATOR MUST TYPE ALL INPUT, S/W FORMS CHECKSUM
30 WIDTH 255:BT$=CHR$(27)+CHR$(40):DM$=CHR$(27)+CHR$(41):POKE 3,0
40 LINE INPUT "}" ,  IN$
50 IF IN$="BYE" THEN STOP
60 IF IN$="FILESEND" THEN GOTO 360
70 REM FORM CHECKSUM AND TACK IT AND CR TO MSG
80 GOSUB 170
90 REM SWITCH CONSLOE TO MODEM
100 GOSUB 270
110 LPRINT DM$;IN$;BT$:PRINT IN$;
120 GOSUB 560
130 REM BACK TO USER AS CONSOLE
140 GOSUB 320
150 PRINT SY$
160 GOTO 40
170 REM CHECKSUM ROUTINW
180 SUM=0
190 FOR I=1 TO LEN(IN$)
200     SUM=SUM+ASC(MID$(IN$,I,1))
210 NEXT I
220 INDEX=(SUM MOD 16)+1
230 C$=MID$("ABCDEFGHIJKLMNOP",INDEX,1)
240 IN$=IN$+C$
250 IN$=IN$+CHR$(13)
260 RETURN
270 REM CONSOLE TO MODEM
280 J=PEEK (3)
290 J=(J AND 252) OR 1
300 POKE 3,J
310 RETURN
320 J=PEEK (3)
330 J=(J AND 252) OR 0
340 POKE 3,J
350 RETURN
360 REM FILE SEND 
370 INPUT "FILE " ;FI$
380 OPEN "I",1,FI$
390 IF EOF(1) THEN 530
400 LINE INPUT #1,DT$
410 IN$="P0Z"+DT$
420 GOSUB 170
430 GOSUB 270
440 LPRINT DM$;IN$;BT$:PRINT IN$;
450 GOSUB 560
460 LPRINT SY$
470 K=INSTR(SY$,"x")
480 IF K<>0 AND K<3 THEN LPRINT CHR$(7) 
490 K=INSTR(SY$,"N")
500 IF K<>0 AND K<3 THEN GOTO 440
510 GOSUB 630
520 GOTO 390
530 GOSUB 320
540 PRINT " *** DONE ***";CHR$(7):CLOSE
550 GOTO 40
560 SY$=""
570 FOR I=1 TO 200
580 TT$=INKEY$
590 IF LEN(TT$)=0 THEN GOTO 610
600 IF ASC(TT$)>31 THEN SY$=SY$+TT$
610 NEXT I
620 RETURN
630 REM QUICK NERVE CHECK
640 GOSUB 320
650 PRINT ">"
660 FOR I=1 TO 5
670 A$=INKEY$
680 IF A$="/" THEN CLOSE : PRINT CHR$(7): GOTO 40
690 NEXT I
700 GOSUB 270
710 RETURN
>"