10 REM*     VOCABULARY DRILL
20 REM*        DAN MIELKE
30 REM*         MAY 1982
40 REM*
50 PRINT CHR$(26)
60 PRINT:PRINT:PRINT
70 PRINT TAB(5);"THIS IS THE FLASHCARD FOR LANGUAGE PRACTICE"
80 PRINT:PRINT
90 PRINT "             SELECT THE FUNCTION"
100 PRINT:PRINT
110 PRINT TAB(10) "(1) INITIALIZE (1ST TIME ONLY!)
120 PRINT TAB(10) "(2) PRACTICE FLASHCARD SERIES"
130 PRINT TAB(10) "(3) ADD WORDS TO EXISTING LIST"
140 PRINT TAB(10) "(4) QUIT"
150 PRINT:PRINT
160 PRINT TAB(10) "WHICH WILL IT BE";
170 INPUT P
180 PRINT CHR$(26)
190 ON P GOTO 210,300,480,630
200 ON ERROR GOTO 50
210 OPEN "O",#1,"B:WORDS"
220 INPUT "ENGLISH";E$
230 IF E$=""THEN 280
240 INPUT "CROW ";Y$
250 PRINT #1,E$;",";Y$
260 PRINT
270 GOTO 220
280 CLOSE #1
290 GOTO 50
300 OPEN "I",#1,"B:WORDS"
310 INPUT "GIVE ENGLISH(1) OR CROW(2)";J
320 IF EOF(1) THEN CLOSE #1:PRINT CHR$(26):PRINT "END OF LIST":GOTO 60
330 INPUT #1,E$,Y$
340 PRINT CHR$(26):PRINT:PRINT:PRINT:PRINT:PRINT:PRINT
350 IF J=1 THEN PRINT TAB(20) E$ ELSE PRINT TAB(20) Y$
360 IF J=1 THEN R$=Y$ ELSE R$=E$
370 PRINT:PRINT:PRINT TAB(20);
380 INPUT G$
390 PRINT:PRINT
400 IF G$=R$ THEN PRINT TAB(20) "RIGHT!":GOTO 420
410 PRINT:PRINT TAB(12) "Should be '"R$;"'."
420 PRINT:PRINT:PRINT:PRINT:PRINT
430 PRINT TAB(10);
440 INPUT "CONTINUE <RETURN> OR QUIT <Q> ";A$
450 IF A$<>"" THEN IF A$<>"Q" THEN 430
460 IF A$="Q" THEN 50
470 GOTO 320
480 OPEN "I",#1,"B:WORDS"
490 OPEN "O",#2,"B:COPY"
500 IF EOF(1) THEN 540
510 LINE INPUT #1,E$
520 PRINT #2,E$
530 GOTO 500
540 CLOSE #1
550 KILL "B:WORDS"
560 INPUT "ENGLISH ";E$
570 IF E$="" THEN 610
580 INPUT "CROW ";Y$
590 PRINT #2,E$;","; Y$
600 PRINT: GOTO 560
610 CLOSE #2
620 NAME "B:COPY" AS "B:WORDS"
630 END
10
580 INPUT "CROW ";Y$
590 PRINT #2