10    VCL$=CHR$(27)+"[2J"+CHR$(27)+"[1;1H"
20    WIDTH 80
30    PRINT VCL$
40    PRINT "     ***  MONDLANDUNG  ***"
50    PRINT 
60    PRINT
70    PRINT "WIRD EINE ANLEITUNG GEW]NSCHT (J ODER N)
80    INPUT A$
90    IF A$="N" THEN 430
100   IF A$="J" THEN 120
110   GOTO 70
120   PRINT 
130   PRINT "SIE LANDEN AUF DEM MOND UND HABEN DIE HANDSTEUERUNG"
140   PRINT "150 METER ]BER DEM LANDEPLATZ ]BERNOMMEN"
150   PRINT "DIE SINKGESCHWINDIGKEIT BETR[GT 15 M/SEC"
160   PRINT "120 TREIBSTOFFEINHEITEN SIND NOCH ]BRIG"
170   PRINT
180   PRINT "BELIEBIGE TASTE   =====>>>  WEITER!"
190   Q$=INKEY$:IF Q$="" THEN 190
200   PRINT VCL$
210   PRINT "ES GELTEN FOLGENDE REGELN :"
220   PRINT "1.) NACH JEDER SEKUNDE WERDEN H\HE, GESCHWINDIGKEIT"
230   PRINT "    UND VERBLEIBENDER TREIBSTOFF ANGEZEIGT"
240   PRINT
250   PRINT "2.) DANACH ERSCHEINT EIN '?'. NUN MUSS DIE ANZAHL AN"
260   PRINT "    IN DER N[CHSTEN SEKUNDE ZU VERBRAUCHENDEN TREIBSTOFFEINHEITEN"
270   PRINT "    EINGEGEBEN WERDEN. JEDE EINHEIT VERRINGERT DIE "
280   PRINT "    SINKGESCHWINDIGKEIT UM 0.3 M/SEC"
290   PRINT
300   PRINT "3.) DER MAXIMALE SCHUB BERTR[GT 9 M/SEC *SEC  ODER"
310   PRINT "    30 TREIBSTOFFEINHEITEN PRO SEKUNDE"
320   PRINT
330   PRINT "4.) BEIM KONTAKT MIT DER OBERFL[CHE WIRD DAS TRIEBWERK"
340   PRINT "    AUTOMATISCH ABGESCHALTET UND ES WERDEN LANDEGESCHWINDIGKEIT"
350   PRINT "    UND VERBLEIBENDER TREIBSTOFF AUSGEGEBEN"
360   PRINT 
370   PRINT "5.) FALLS DER TREIBSTOFF AUSGEHT, ERSCHEINT DAS '?'"
380   PRINT "    NICHR MEHR, ABER DIE DATEN WERDEN WEITERHIN "
390   PRINT "    JEDE SEKUNDE BIS ZUR LANDUNG AUSGEGEBEN"
400   PRINT
410   PRINT "BELIEBIGE TASTE UND ES GEHT LOS ! ! !"
420   Q$=INKEY$:IF Q$="" THEN 420
430   PRINT VCL$
440   PRINT "      B E G I N N   D E R   L A N D U N G   . . . ."
450   PRINT  
460   PRINT "         V I E L    G L ] C K  ! ! ! "
470   GOSUB 490
480   GOTO 510
490   PRINT "SEK HOEHE GESCHW. TREIBST. GRAFIK DER ENTFERNUNG"
500   RETURN
510   T=0 
520   H=150
530   V=15
540   F=120
550   IF B = 0 THEN 630
560   IF T=10 OR T=20 OR T=30 THEN GOSUB 490
570   PRINT  USING "##";T;TAB(4);
580   PRINT USING "###.##";H;TAB(12);
590   PRINT USING "##.##";V;TAB(20);
600   PRINT USING "###";F;TAB(27);
610   PRINT "I";TAB(H/3+28);"**"
620   GOTO 690
630   IF T=10 OR T=20 OR T=30 THEN GOSUB 490
640   PRINT  USING "##";T;TAB(4);
650   PRINT USING "###.##";H;TAB(12);
660   PRINT USING "##.##";V;TAB(20);
670   PRINT USING "###";F;TAB(27);
680   PRINT "I";TAB(H/3+29);"**"
690   INPUT B
700   IF B < 0 THEN 890
710   IF B > 30 THEN 890
720   IF B > F THEN 740
730   GOTO 750
740   B=F
750   V1 = V-B*.3+1.5
760   F=F-B
770   H=H-.5*(V+V1)
780   IF H <=0 THEN 910
790   T = T + 1
800   V=V1
810   IF F > 0 THEN 550    
820   IF B = 0 THEN 840
830   PRINT "*** KEIN TREIBSTOFF MEHR ***"
840   PRINT  USING "##";T;TAB(4);
850   PRINT USING "###.##";H;TAB(12);
860   PRINT USING "##.##";V;TAB(20);
870   PRINT USING "###";F;TAB(27);
880   PRINT "I";TAB(H/3+29);"**"
890   B =0
900   GOTO 750
910   PRINT "*****   KONTAKT   *****"
920   H=H+.5*(V+V1)
930   IF B = 5 THEN 960
940   D = (-V+SQR(V*V+H*(3-.6*B)))/(1.5-.3*B)
950   GOTO 970
960   D=H/V
970   V1 = V+(1.5-.3*B)*D
980   PRINT  "LANDUNG NACH ";T+D;"SEKUNDEN"
990   PRINT  "LANDUNGSGESCHWINDIGKEIT = ";V1;"M/SEC DAS ENTSPRICHT: ";V1*3.6;"KM/STD"
1000  PRINT F;"TREIBSTOFFEINHEITEN SIND ]BRIG"
1010  IF V1 > -0.5 AND V1 < 0.5 THEN 1020 ELSE 1040
1020  PRINT  "G R A T U L A T I O N   : EINE PERFEKTE LANDUNG"
1030  PRINT "DIE LIZENZ WIRD ERNEUERT  .... SP[TER"
1040  IF ABS (V1) < 5 THEN 1070
1050  PRINT "*****  BRUCHLANDUNG   *****"
1060  PRINT "BEILEIDSSCHREIBEN AN IHRE N[CHSTEN ANGEH\RIGEN WERDEN VERSCHICKT"
1070  PRINT "NOCHMAL ? (J/N)"
1080  INPUT A$
1090  IF A$ = "J" THEN 440
1100  IF A$ = "N" THEN 1130
1110  GOTO 1070
1120  PRINT
1130  CHAIN "CSPIEL"
