; M7NP-DMV.ASM -- NCR Personal Computer (Decision Mate V model)
;		overlay file for MDM7xx.  04/09/84.
;
; You will want to look this file over carefully. There are a number of
; options that you can use to configure the program to suit your taste.
; This file adapts the NCR Decision Mate V computer to the modem program.
; Much of the information contained here is not in the MDM712.ASM file.
;
; Edit this file for your preferences then follow the "TO USE:" example
; shown below.
;
; Use the "SET" command to change the baudrate when desired.  It starts
; out at 300 baud when the program is first called up.
;
;	TO USE: First edit this file filling in answers for your own
;		equipment.  Then assemble with ASM.COM or equivalent
;		assembler.  Then use DDT to overlay the the results
;		of this program to the original .COM file:
;
;		A>DDT MDM7xx.COM        (old version file name)
;		DDT VERS 2.2
;		NEXT  PC
;		4A00 0100
;		-IM7NP-DMV.HEX		(note the "I" command)
;		-R			("R" loads in the .HEX file)
;		NEXT  PC
;		4A00 0100
;		-G0			(return to CP/M)
;		A>SAVE 73 MDM7yy.COM	(now have a modified .COM file)
;		       ==		(this number changes with version)
;
; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
;
; 04/09/84 - Renamed for new MDM7xx conventions - Mike Shapiro
; 01/03/84 - Renamed for NCR Personal Computer  - Mike Shapiro
;	     Changed ^O to ^L to conform to original.
; 12/08/83 - Modified for NCR Decision Mate V   - Mike Shapiro
; 07/01/83 - Revised to work with MDM711	- Irv Hoff
; 06/22/83 - Revised to work with MDM710	- Irv Hoff
; 05/25/83 - Revised to work with MDM709	- Irv Hoff
; 04/15/83 - Revised to work with MDM708	- Irv Hoff
; 04/11/83 - Updated to work with MDM707	- Irv Hoff
; 04/04/83 - Updated to work with MDM706	- Irv Hoff
; 02/27/83 - Updated to work with MDM705	- Irv Hoff
; 02/17/83 - Modified MDM703CF for Kaypro II
;	     computers with external modems	- Irv Hoff
;
; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
;
BELL:		EQU	07H		;bell
CR:		EQU	0DH		;carriage return
ESC:		EQU	1BH		;escape
LF:		EQU	0AH		;linefeed
;
YES:		EQU	0FFH
NO:		EQU	0
;
;
PORT:					;2651 REGISTER ADDRESSING
MODWXMT:	EQU	74H		;NCR DM-V serial output port
MODRSTA:	EQU	71H   		;Modem status port
MODRRCV:	EQU	70H 		;Modem data port
MODWCMD:	EQU	77H   		;Modem control port
MODWMOD:	EQU	76H		;Modem baud rate port
;
MODRCVB:	EQU	02H		;Your bit to test for receive
MODRCVR:	EQU	02H		;Your value when receive ready
MODSNDB:	EQU	01H		;Your bit to test for send
MODSNDR:	EQU	01H		;Your value when send ready		
;
;
		ORG	100H
;
;
; Change the clock speed as needed for your system.
;
		DS	3	;(for  "JMP   START" instruction)
;
PMMIMODEM:	DB	NO	;yes=PMMI S-100 Modem			103H
SMARTMODEM:	DB	NO 	;yes=HAYES Smartmodem, no=non-PMMI	104H
TOUCHPULSE:	DB	'T'	;T=touch, P=pulse (Smartmodem-only)	105H
CLOCK:		DB	40	;clock speed in MHz x10, 25.5 MHz max.	106H
				;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
MSPEED:		DB	1	;0=110 1=300 2=450 3=600 4=710 5=1200   107H
				;6=2400 7=4800 8=9600 9=19200 default=1
BYTDLY:		DB	5	;0=0 delay  1=10ms  5=50 ms - 9=90 ms   108H
				;default time to send character in ter-
				;minal mode file transfer for slow BBS.
CRDLY:		DB	5	;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
				;default time for extra wait after CRLF
				;in terminal mode file transfer
NOOFCOL:	DB	5	;number of DIR columns shown		10AH
SETUPTST:	DB	YES	;yes=user-added Setup routine		10BH
SCRNTEST:	DB	YES	;Cursor control routine 		10CH
ACKNAK:		DB	YES	;yes=resend a record after any non-ACK	10DH
				;no=resend a record after a valid NAK
BAKUPBYTE:	DB	NO	;yes=change any file same name to .BAK	10EH
CRCDFLT:	DB	YES	;yes=default to CRC checking		10FH
TOGGLECRC:	DB	YES	;yes=allow toggling of CRC to Checksum	110H
CONVBKSP:	DB	NO	;yes=convert backspace to rub		111H
TOGGLEBK:	DB	NO	;yes=allow toggling of bksp to rub	112H
ADDLF:		DB	NO	;no=no LF after CR to send file in	113H
				;terminal mode (added by remote echo)
TOGGLELF:	DB	YES	;yes=allow toggling of LF after CR	114H
TRANLOGON:	DB	YES	;yes=allow transmission of logon	115H
				;write logon sequence at location LOGON
SAVCCP:		DB	YES	;yes=do not overwrite CCP		116H
LOCONEXTCHR:	DB	NO	;yes=local command if EXTCHR precedes	117H
				;no=external command if EXTCHR precedes
TOGGLELOC:	DB	YES	;yes=allow toggling of LOCONEXTCHR	118H
LSTTST:		DB	YES	;yes=printer available on printer port	119H
XOFFTST:	DB	NO	;yes=chcks for XOFF from remote while	11AH
				;sending a file in terminal mode
XONWAIT:	DB	NO	;yes=wait for XON after CR while	11BH
				;sending a file in terminal mode
TOGXOFF:	DB	YES	;yes=allow toggling of XOFF checking	11CH
IGNORCTL:	DB	YES	;yes=CTL-chars above ^M not displayed	11DH
EXTRA1:		DB	0	;for future expansion			11EH
EXTRA2:		DB	0	;for future expansion			11FH
BRKCHR:		DB	'@'-40H	;^@ = Send a 300 ms. break tone		120H
NOCXNNCT:	DB	'N'-40H	;^N = Disconnect from the phone line	121H
LOGCHR:		DB	'L'-40H	;^L = Send logon			122H
LSTCHR:		DB	'P'-40H	;^P = Toggle printer			123H
UNSAVE:		DB	'R'-40H	;^R = Close input text buffer		124H
TRANCHR:	DB	'T'-40H ;^T = Transmit file to remote		125H
SAVECHR:	DB	'Y'-40H	;^Y = Open input text buffer		126H
EXTCHR:		DB	'^'-40H	;^^ = Send next character		127H
;
;
		DS	2		;used for PMMI			128H
;
IN$MODCTL1:	IN	MODRSTA	! RET	;get the status bits		12AH
		DS	7
OUT$MODDATP:	OUT	MODWXMT ! RET	;out modem data port		134H
		DS	7
IN$MODDATP:	IN	MODRRCV ! RET	;in modem data port		13EH
		DS	7
ANI$MODRCVB:	ANI	MODRCVB	! RET	;bit to test for receive ready	148H
CPI$MODRCVR:	CPI	MODRCVR ! RET	;value of receive bit when rdy	14BH
ANI$MODSNDB:	ANI	MODSNDB	! RET	;bit to test for send ready	14EH
CPI$MODSNDR:	CPI	MODSNDR	! RET	;value of send bit when ready	151H
;
IN$BAUDRP:	RET  !	NOP  !  NOP	;input baud port (not used)	154H
OUT$BAUDRP:	RET  !	NOP  !	NOP	;output baud port (not used)	157H
OUT$MODCTL1:	RET  !	NOP  !	NOP	;out modem control port (unused)15AH
OUT$MODCTL2:	RET  !	NOP  !	NOP	;out modem status port (unused)	15DH
;
;
LOGONPTR:	DW	LOGON		;for user message.		160H
		DS	3		;dial routine			162H
		DS	3		;disconnect routine		165H
JMP$GOODBYE:	JMP	GOODBYE		;				168H
JMP$INITMOD:	JMP	INITMOD		;go to user written routine	16BH
		RET  !  NOP  !  NOP	;(by-passes PMMI routine)	16EH
		RET  !  NOP  !  NOP	;(by-passes PMMI routine)	171H
		RET  !  NOP  !  NOP	;(by-passes PMMI routine)	174H
JMP$SETUPR:	JMP	SETUPR		;				177H
JMP$SPCLMENU:	JMP	SPCLMENU	;				17AH
JMP$SYSVER:	JMP	SYSVER		;				17DH
JMP$BREAK:	JMP	SENDBRK		;				180H
;
;
; Do not change the following six lines.
;
JMP$ILPRT:	DS	3		;				183H
JMP$INBUF	DS	3		;				186H
JMP$INLNCOMP:	DS	3		;				189H
JMP$INMODEM	DS	3		;				18CH
JMP$NXTSCRN:	DS	3		;				18FH
JMP$TIMER:	DS	3		;				192H
;
;
; Clear sequences -- CLREOS is clear to end of screen, CLRSCRN is clear
; entire screen.  Last entry must be 0.  Any other 0's act as NOP's.
;
CLREOS:		CALL	JMP$ILPRT	;				195H
		DB	01BH,79H,0,0,0	;<ESC>Y				198H
		RET			;				19DH
;
CLRSCRN:	CALL	JMP$ILPRT	;				19EH
		DB	01BH,3AH,0,0,0	;<ESC>*				1A1H
		RET			;				1A6H
;
;
SYSVER:		CALL	JMP$ILPRT	;				1A7H
		DB	'for NCR Personal Computer (1.2)',CR,LF
		DB	'                            ',CR,LF ;message
		DB	'                            ',CR,LF ;space
		DB	0		;required terminator byte
		RET
;.....
;
;
;-----------------------------------------------------------------------
;
; NOTE:  You can change the SYSVER message to be longer or shorter.  The
;	 end of your last routine should terminate by 0380H (473 bytes
;	 available after start of SYSVER) if using the Hayes Smartmodem
;	 or by address 0B80H (2521 bytes) otherwise.
;
;-----------------------------------------------------------------------
;
; You can put in a message at this location which can be called up with
; CTL-O if TRANLOGON has been set YES.  You can put in several lines if
; desired.  End with a 0.
;
LOGON:	  DB	'for NCR Personal Computer (installed by Mike Shapiro, '
	  DB	'Apr. 1984.)',CR,LF,0
;.....
;
;
; This routine allows a 300 ms. break tone to be sent to reset some
; time-share computers.
;
SENDBRK:  MVI	A,38H		;RTS/LO+RESET+BREAK+DTR/HI
	  JMP	GOODBYE1
;
;.....
;
; This routine sends a 300 ms. break tone and sets DTR low for the same
; length of time to disconnect some modems such as the Bell 212A, etc.
;
GOODBYE:  MVI	A,3AH		;RTS/LO+RESET+BREAK+DTR/LO
;
GOODBYE1: OUT	MODWCMD
	  MVI	B,3		;DELAY 300 MS.
	  CALL	JMP$TIMER
	  MVI	A,37H		;RTS/LO+RXEN+DTR/LO+TXEN
	  OUT	MODWCMD
	  RET
;.....
;
;
; NCR Decision Mate V initialization
;
;
INITMOD:  MVI	A,00H		;DISABLE EVERYTHING
	  OUT	MODWCMD
	  MVI	A,10H		;RESET
	  OUT	MODWCMD
	  OUT	MODWCMD
	  MVI	A,10H		;RESET
	  OUT	MODWCMD
	  CALL	SETBAUD		;SET THE BAUD RATE
	  MVI	A,37H		;RTS/LO+RESET+RXEN+DTR/LO+TXEN
	  OUT	MODWCMD
	  RET
;
;		ON ENTRY MSPEED MUST HAVE APPROPRIATE VALUE
;		AND SETBAUD3 MUST HAVE MATCHING VALUE FOR PORT
;
SETBAUD:  LDA	MSPEED		;SET THE BAUD RATE
	  CPI	01		;CHECK FOR >=300 BAUD
	  MVI	A,4EH		;1 STOP+PAR DIS+8 BIT+16 X RATE
	  JNC	SETBAUD1	;IF 300 OR MORE, OK
	  ORI	80H		;CHANGE TO 2 STOP BITS FOR 110
;
SETBAUD1: OUT	MODWMOD		;SEND TO BAUD RATE PORT
;
SETBAUD2: LDA	SETBAUD3	;INTERNAL CLOCK SELECT+BAUD RATE 
	  OUT	MODWMOD		;SEND TO BAUD RATE PORT
	  RET
;
SETBAUD3: DB	35H		;BAUD RATE BYTE (INITIALLY 300)
;.....				;  + INTERNAL XMT/RCV CLOCKS
;
;
; Sets the modem speed via the SET command.
;
SETUPR:	  LXI	D,BAUDBUF	;POINT TO NEW INPUT BUFFER
	  CALL	JMP$ILPRT
	  DB	'Enter new baud rate (300, 600, 1200, 4800, or 9600)? ',0
	  CALL	JMP$INBUF
	  LXI	D,BAUDBUF+2
	  CALL	JMP$INLNCOMP	;COMPARE BAUDBUF+2 WITH CHARACTERS BELOW
	  DB	'300',0
	  JNC	OK300		;GO IF GOT MATCH
	  CALL	JMP$INLNCOMP
	  DB	'600',0
	  JNC	OK600
	  CALL	JMP$INLNCOMP
	  DB	'1200',0
	  JNC	OK1200
	  CALL	JMP$INLNCOMP
	  DB	'4800',0
	  JNC	OK4800
	  CALL	JMP$INLNCOMP
	  DB	'9600',0
	  JNC	OK9600
	  CALL	JMP$ILPRT	;ALL MATCHES FAILED, TELL OPERATOR
	  DB	'++ Incorrect entry ++',CR,LF,BELL,0
	  JMP	SETUPR		;TRY AGAIN
;
OK300:	  MVI	A,1
	  LHLD	BD300
	  JMP	LOADBD
;
OK600:	  MVI	A,3
	  LHLD	BD600
	  JMP	LOADBD
;
OK1200:	  MVI	A,5
	  LHLD	BD1200
	  JMP	LOADBD
;
OK4800:	  MVI	A,7
	  LHLD	BD4800
	  JMP	LOADBD
;
OK9600:	  MVI	A,8
	  LHLD	BD9600
;
LOADBD:	  STA	MSPEED		;CHANGE TIME-TO-SEND TO MATCH BAUDRATE
	  MOV	A,L		;GET BAUDRATE BYTE
	  STA	SETBAUD3	;SET UP TO SEND TO PORT
	  JMP	SETBAUD		;REINITIALIZE TO NEW BAUDRATE, THEN DONE
;
;
; TABLE OF BAUDRATE PARAMETERS (30H+BAUD RATE CODE FOR INT XMT/RCV CLOCK)
;
BD300:	  DW	0035H		;300 BAUD
BD600:	  DW	0036H		;600 BAUD
BD1200:	  DW	0037H		;1200 BAUD
BD4800:	  DW	003CH		;4800 BAUD
BD9600:	  DW	003EH		;9600 BAUD
;
BAUDBUF:  DB	10,0		;BAUD RATE ENTRY BUFFER
	  DS	10
;
;-----------------------------------------------------------------------
;
; The following routine can be used as an auxiliary menu for notes of
; interest to a particular computer, etc.  If using the Hayes Smartmodem
; this is unavailable without a spcial address change.
;
SPCLMENU: RET
;
;-----------------------------------------------------------------------
;
;
; NOTE:  MUST TERMINATE PRIOR TO 0380H (with Smartmodem)
;				 0B80H (without Smartmodem)
;
	  END	100H
