	PAGE 60
	ENTRY FRAME
	EXT VECTOR,XMIN,YMIN,XMAX,YMAX
	.Z80
	.COMMENT #

FRAME

plottet einen Rahmen um das momentane Plott-Fenster.

Die Routine benutzt die externen Fenster-Koordinaten XMIN,YMIN und XMAX,YMAX
im Modul PUTP und ruft die Plott-Routine VECTOR.

A.Herrmann	27.12.83
#
FRAME:	XOR A		; Clear Flags
	LD HL,(XMAX)
	LD DE,(XMIN)
	SBC HL,DE
	LD (DX),HL
	LD HL,0
	LD (DY),HL
	LD HL,ZERO
	LD DE,ZERO
	LD BC,PTR
	CALL VECTOR	; Vector 0,0 x,0
;
	XOR A
	LD HL,(YMAX)
	LD DE,(YMIN)
	SBC HL,DE
	LD (DY),HL
	LD HL,(DX)
	PUSH HL
	LD HL,0
	LD (DX),HL
	LD HL,ZERO
	LD DE,ZERO
	LD BC,PTR
	CALL VECTOR	; Vector 0,0 0,y
;
	POP HL
	LD (DX),HL
	LD HL,DX
	LD DE,ZERO
	LD BC,PTR
	CALL VECTOR	; Vector x,0 x,y
;
	LD HL,ZERO
	LD DE,DY
	LD BC,PTR
	CALL VECTOR	; Vector 0,y x,y
	RET
;
ZERO:	DW 0
DX:	DW 0
DY:	DW 0
PEN:	DW 1
PTR:	DW DX
	DW DY
	DW PEN
;
	END
