;	V24
;	initialisiert die SIO-A
;	und schaltet das LST:-Device 
;	im IO-Byte auf die SIO-A um.
;
;	18.10.84
;
	.Z80
	ENTRY V24

SIOAC	EQU 06		;CONTROL PORT NO.
SIOAD	EQU 04		;DATA PORT NO.
IOBYTE	EQU 03		;IO-BYTE ADDRESS
CCP	EQU 0C800H	;CCP ENTRY ADDRESS
;
V24:	LD HL,BLOCK
	LD C,SIOAC
	LD B,LNGTH
	OTIR
	LD A,21H
	LD (IOBYTE),A
;
	LD B,0		;256 MAL "A" RAUS
RAUS:	IN A,(SIOAC)
	BIT 2,A
	JR Z,RAUS
	LD A,41H
	OUT (SIOAD),A
	DJNZ RAUS
;
	LD C,0		;DRIVE A, USER 0
	JP CCP
;
BLOCK:	DB 00011000B	;WR0 RESET
	DB 00010100B	;SELECT WR4
	DB 11000100B	;x64 CLOCK, 1 STOP BIT, NO PARITY
	DB 00010011B	;SELECT WR3
	DB 11000001B	;8 BIT, Rx ENABLE
	DB 00010101B	;SELECT WR5
	DB 01101010B	;NO DTR, 8 BIT, Tx ENABLE, RTS
LNGTH	EQU $-BLOCK
;
	END
