10 REM	G
20 REM	GENERIERT EINEN DOWN LOAD FILE FUER DEN TYPENRADDRUCKER F10-55.
30 REM
40 REM	A.HERRMANN	03.11.84
50 REM
100 DIM ADR%(95)	'SPOKE ADDRESS
110 DIM HAM%(95)	'HAMMER ENERGY
120 DIM PRO%(95)	'PROPORTIONAL PITCH
130 DIM RIB%(95)	'RIBBON ADVANCE
140 '
1000 PRINT CHR$(&HC);"ENTER DOWN LOAD FILE NAME ";
1010 INPUT NAM$
1100 PRINT "ENTER PRINT WHEEL SPOKE ADDRESS IN DECIMAL"
1110 FOR I%=0 TO 95		'96 BYTES
1120 PRINT "HEX ";HEX$(32+I%),
1130 INPUT ADR%(I%)
1140 NEXT I%
1150 PRINT 
1200 PRINT "ENTER HAMMER ENERGY DATA IN HEX"
1210 FOR I%=0 TO 95		'96 BYTES
1220 PRINT "HEX ";HEX$(32+I%), : INPUT;C$
1230 HAM%(I%) = (ASC(MID$(C$,1,1))-48)*16
1232 J%=ASC(MID$(C$,2,1))-48 : IF J%>9 THEN J%=J%-7
1234 HAM%(I%) = HAM%(I%) + J%
1236 PRINT "  = ";HEX$(HAM%(I%))
1240 NEXT I%
1250 PRINT 
1300 PRINT "ENTER PROPOTIONAL SPACING PITCH IN DECIMAL"
1310 FOR I%=0 TO 95		'96 BYTES
1320 PRINT "HEX ";HEX$(32+I%),
1330 INPUT PRO%(I%)
1340 NEXT I%
1350 PRINT 
1400 PRINT "ENTER RIBBON ADVANCE DATA IN DECIMAL"
1410 FOR I%=0 TO 95		'96 BYTES
1420 PRINT "HEX ";HEX$(32+I%),
1430 INPUT RIB%(I%)
1440 NEXT I%
1450 PRINT 
1500 PRINT "MIXING PRO AND RIB DATA"
1510 FOR I%=0 TO 95		'96 BYTES
1520 PRINT "HEX ";HEX$(32+I%),
1530 PRO%(I%)=PRO%(I%) + 16*RIB%(I%) : PRINT HEX$(PRO%(I%))
1540 NEXT I%
1550 PRINT 
1600 PRINT "GENERATING CHARACTER STRING FOR SPOKE ADDRESS"
1602 ADR$=SPACE$(96)
1610 FOR I%=0 TO 95		'96 BYTES
1620 MID$(ADR$,I%+1,1)=MKI$(ADR%(I%))
1640 NEXT I%
1700 PRINT "GENERATING CHARACTER STRING FOR HAMMER DATA"
1702 HAM$=SPACE$(96)
1710 FOR I%=0 TO 95		'96 BYTES
1720 MID$(HAM$,I%+1,1)=MKI$(HAM%(I%))
1740 NEXT I%
1800 PRINT "GENERATING CHARACTER STRING FOR PRO AND RIB DATA"
1802 PRO$=SPACE$(96)
1810 FOR I%=0 TO 95		'96 BYTES
1820 MID$(PRO$,I%+1,1)=MKI$(PRO%(I%))
1840 NEXT I%
1850 PRINT 
2000 PRINT "WRITING ESC CODES AND STRINGS TO FILE ";NAM$;
2010 OPEN "O",#1,NAM$
2020 PRINT#1,CHR$(&H1B);"<";ADR$;HAM$;PRO$;CHR$(&H1B);">";
2030 CLOSE#1
2090 PRINT
3000 PRINT : PRINT "RESTART ? (Y/N) ";
3010 C$=INPUT$(1) : PRINT C$ 
3020 IF C$="Y" OR C$="y" GOTO 1000
4000 END
90 PRINT
3000 PRINT : PRINT "RESTA