		SAMPLE ALIAS.CMD FILE FOR USE WITH NZCOM
		----------------------------------------



;; HDBACK40 ALIASES, BY RICK CHARNES OUTTAKES, NOT COMPLETE
;;
;; INCORPORATE THE FOLLOWING ALIAS, WHICH IN TURN CALLS STARTUP.ZEX,
;; INTO YOUR STARTUP ROUTINE:
NOTIZ
START		ZEX START %DAY %MONTH $RF02 $DY $RF03:$DN $DA
;;
INPUTERA	$"^j^mEnter files to erase as a filelist:  "IF ~NU $'L1;ERASE $'L1;SP;ELSE;ECHO ^M^J N%>OTHING ENTERED!;FI
INPUT		$Z$"^m^jEnter penultimate command ^[) ('EXIT' to exit ZEX completely):  ^[("$ZIF EQ $'E1 EXIT;ECHO ^M^JR%>ETURNING TO %<ZCPR3...;RS %CURDU;POKE $+M0008 0;ELSE;$'L1;FI
INPUTRET	$Z$"^m^jEnter final command ^[)('EXIT' to exit ZEX completely):  ^[("$ZFI;IF EQ $'E1 EXIT;ECHO ^M^JA%>BORTING %<ZEX %>SCRIPT...;RS %CURDU;POKE $+M0008 0;ELSE;$'L1;RS E R%>ETURNING TO %<ZEX %>SCRIPT AT LETTER%< %$RF05...;HOLD 2;FI

DIR		SDZ $*

THIS ALIAS PROVIDES A DIRECTORY-DISPLAY COMMAND IN WHICH THE FILE
 ; SPECIFICATION IS AUTOMATICALLY WILDCARDED.  IT SAVES THE TROUBLE OF
 ; HAVING TO TYPE ASTERISKS MANUALLY.

D!=SD/	        SDZ $TD1$TU1:$TN1*.$TT1* $-1

 ; THIS ALIAS IS USED WITH THE SYNTAX NAME DU:DIR PW OR NAME DIR PW TO ASSIGN
 ; THE NAMED DIRECTORY DIR TO THE DESIGNATED (OR CURRENT) DRIVE/USER.  THE
 ; SECOND TOKEN IS OPTIONAL; IF PRESENT, IT WILL ASSIGN A PASSWORD AS WELL.

NAME=SETNAME	EDITNDR $TD1$TU1:$TN1 $2 \X

 ; THIS ALIAS WILL BE USED INSTEAD OF AN INBUILT TYPE COMMAND

TYPE		SCAN $1

 ; THIS ALIAS HELPS TO VIEW AND EXTRACT .LZW FILES CREATED BY LHARC
 
LHARC=LHRD	LHRD $1

 ; this will format a disc on a Computer with CP/M PLUS and prepare DS

CREATE=MAKEDISK	format $1;zex initime $1;set $1[name=$"DISKNAME> "$'L1,create,update]

make=initdir $1;set $1[name=$"DISKNAME> "$'L1,create,update]

 ; THIS ALIAS CAN HELP TO TEMPORARILY CHANGE A DU: NAME

RENDIR		NAME10 $1

 ; THIS ALIAS HELPS TO REMEDY THE TCAP PROBLEMS OF V

V!=V		V $1

 ; THIS ALIAS WILL SAVE THE CURRENTLY DEFINED NAMED DIRECTORIES IN THE FILE
 ; A0:NZCOM.NDR.  IF A COMMAND TAIL BEGINNING WITH 'L' (FOR LIBRARY) IS
 ; INCLUDED, THE FILE WILL BE PUT INTO NZCOM.LBR SO THAT IT WILL AUTOMATICALLY
 ; BE LOADED AT Z-SYSTEM COLD BOOT AND THE INDIVIDUAL NDR FILE WILL BE ERASED.

PUTNDR		SAVENDR A0:NZCOM;IF EQ $1 L*;LPUT A0:NZCOM A0:NZCOM.NDR;ERA A0:NZCOM.NDR;FI

 ; THIS ALIAS WILL ALLOW YOU TO EXAMINE A FILE.  IT LOADS THE FILE INTO THE
 ; TPA AND THEN USES THE RCP PEEK COMMAND TO EXAMINE IT.  IT WILL LOAD A FILE
 ; FROM THE CURRENT DIRECTORY EVEN IF THAT DIRECTORY IS NOT ON THE PATH.

LOOK		GET 100 $TD1$TU1:$TF1;P 100

 ; THIS IS AN ALIAS FOR THE COMPLEX INPUT LINE OF SEARCH22

FIND		D0:SEARCH $1 L =$2

 ; THIS ALIAS REMOVES NZCOM AND RESTORES THE OPERATION OF CP/M.

OFF=EXIT	NZCPM

 ; THIS IS TO QUIT Z3PLUS

CPM		Z3PLUS OFF

 ; THIS ALIAS PROVIDES A SHORTHAND FOR THE CRUNCH COMMAND.

CR,UNCH		CRUNCH $*

 ; THIS IS A SHORTCUT TO TAKING A NOTE IN A CERTAIN FILE WITH NT3

NOTIZ=NT	 ECHO 		  NOTIZBLOCK -  BITTE  EINGEBEN! 	
;NT46 G4:PROJEKTE.TXT

 ; CPC CP/M 2.2 IS VERY SENSITIVE TO SCREEN DISTURBANCE. MOST OF THE TIME
 ; THE CURSOR SIMPLY VANISHES. THIS IS A SIMPLE REMEDY TO TURN IT ON AGAIN.

CURSOR		ECHO 

 ; THIS ALIAS ALLOWS PASSING DIRECT TERMINAL COMMANDS TO THE SCREEN

CONTROL=CRT	SCREEN

 ; THE FOLLOWING PAIR OF ALIASES AUTOMATES A RECURSIVE INVOCATION OF SOME
 ; OTHER COMMAND LINE.  IT IS INVOKED AS RECURSE COMMANDLINE.

REC,URSE	IF NU $1;ECHO;ECHO %<  S%>YNTAX: %<$0 CMDNAME [PARAMETERS];ECHO;ELSE; RECURSE2 $*;FI
RECURSE2	FI;$*;IF IN R%>UN %<"$1" %>AGAIN? ; $0 $*

 ; THE FOLLOWING ALIAS WILL HELP HELP TO SEARCH ON A SPECIFIED USER "HELPS"
 ; IN ORDER TO HAVE ALL IN PLACE.
H=HELP          HELP $1                 

 ; THE FOLLOWING ALIAS WILL HELP HELP TO SEARCH ON A SPECIFIED USER "HELPS"
 ; IN ORDER TO HAVE ALL IN PLACE.

Z=ZHELP          LHC -e:$1 $1

 ; THE FOLLOWING PAIR OF ALIASES AUTOMATES THE REPEATED INVOCATION OF A
 ; COMMAND THAT TAKES A SINGLE ARGUMENT.  IT IS INVOKED AS
 ; REPEAT COMMAND ARG1 ARG2 ... ARGN.  THE COMMAND COMMAND IS EXECUTED
 ; IN SEQUENCE, FIRST WITH ARG1, THEN WITH ARG2, AND SO ON.

REP,EAT		IF NU $2;ECHO;ECHO %<  S%>YNTAX: %<$0 CMDNAME ARG1 ARG2 ...;ECHO;ELSE; REPEAT2 $*;FI
REPEAT2		FI;$1 $2;IF ~NU $3; REPEAT2 $1 $-2

 ; MEMORY DISPLAY ALIASES -- THESE ALIASES USE THE PEEK COMMAND TO SHOW THE
 ; CONTENTS OF VARIOUS SYSTEM MODULES

PBIOS=BIOS		P $AB
PCCP=CCP=PCPR=CPR	P $AC
PDOS=DOS		P $AD
PENV=ENV		P $AE
PFCP=FCP		P $AF
PIOP=IOP		P $AI
PMCL=MCL		P $AL
PMSG=MSG		P $AM $+M004F
PNDR=NDR		P $AN
PPATH			P $AP $+P000F
PRCP=RCP		P $AR
PSHL=PSHELL=SHL=SHELL	P $AS $+S007F
PXFCB=XFCB=PFCB=FCB	P $AX $+X0023
